cmake/cmake.d/03-extra_targets.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20
  21 #--------------------------------------------------------------------------
  22 #  WARNING:
  23 #     Do not change this cmake template
  24 #     Customise your preferences in "./conf.d/cmake/config.cmake"
  25 #--------------------------------------------------------------------------
  26
  27 # Add a dummy target to enable global dependency order
  28 # -----------------------------------------------------
  29 if(EXTRA_DEPENDENCIES_ORDER)
  30         set(DEPENDENCIES_TARGET ${PROJECT_NAME}_extra_dependencies)
  31         add_custom_target(${DEPENDENCIES_TARGET} ALL
  32                 DEPENDS ${EXTRA_DEPENDENCY_ORDER}
  33         )
  34 endif()
  35
  36 # Add RSYNCTARGET
  37 remote_targets_populate()
  38
  39 # ----------------------------------------------------------------------------
  40 #                                Archive target
  41 # ----------------------------------------------------------------------------
  42 add_custom_command(OUTPUT  ${ARCHIVE_OUTPUT}
  43         DEPENDS ${PROJECT_TARGETS}
  44         #Create git archive of the main project
  45         COMMAND cd ${CMAKE_CURRENT_SOURCE_DIR}\; git --git-dir=${CMAKE_CURRENT_SOURCE_DIR}/.git archive --format=tar --prefix=${NPKG_PROJECT_NAME}-${PROJECT_VERSION}/ HEAD -o ${ARCHIVE_OUTPUT_ARCHIVE}
  46         #Create tmp git archive for each submodule
  47         COMMAND cd ${CMAKE_CURRENT_SOURCE_DIR}\; git --git-dir=${CMAKE_CURRENT_SOURCE_DIR}/.git submodule foreach --recursive ${CMD_ARCHIVE_SUBMODULE}
  48         #Concatenate main archive and tmp submodule archive
  49         COMMAND  for SUBTAR in ${TMP_ARCHIVE_SUBMODULE}-*.tar\; do tar --concatenate --file=${ARCHIVE_OUTPUT_ARCHIVE} $$SUBTAR\;done
  50         #Remove tmp submodule archive
  51         COMMAND rm -rf ${TMP_ARCHIVE_SUBMODULE}-*.tar
  52         #Compress main archive
  53         COMMAND gzip --force --verbose ${ARCHIVE_OUTPUT_ARCHIVE}
  54 )
  55 add_custom_target(archive DEPENDS ${ARCHIVE_OUTPUT})
  56
  57 # ----------------------------------------------------------------------------
  58 #                                Packaging target
  59 # ----------------------------------------------------------------------------
  60 #Format Build require package
  61 foreach (PKG_CONFIG ${PKG_REQUIRED_LIST})
  62         #Unset TMP variable
  63         unset(XPREFIX)
  64         unset(XRULE)
  65         unset(RPM_EXTRA_DEP)
  66         unset(DEB_EXTRA_DEP)
  67         #For deb package,add EOL format only for a new line
  68         if(DEB_PKG_DEPS)
  69                 set(DEB_PKG_DEPS "${DEB_PKG_DEPS},\n")
  70         endif()
  71         #Get pkg-config rule on version
  72         string(REGEX REPLACE "[<>]?=.*$" "" XPREFIX ${PKG_CONFIG})
  73         string(REGEX MATCH "[<>]?="  XRULE ${PKG_CONFIG})
  74         #Only if pkg-config has rule on version
  75         if(XRULE)
  76                 string(REGEX REPLACE ".*[<>]?=" "" XVERS ${PKG_CONFIG})
  77                 set(RPM_EXTRA_DEP " ${XRULE} ${XVERS}")
  78                 set(DEB_EXTRA_DEP " (${XRULE} ${XVERS})")
  79         endif()
  80         # Format for rpm package
  81         set(RPM_PKG_DEPS "${RPM_PKG_DEPS}BuildRequires: pkgconfig(${XPREFIX})${RPM_EXTRA_DEP}\n")
  82
  83         # Format for deb package
  84         # Because the tool "dpkg" is used on the packages db to find the
  85         # package providing the pkg-cong file ${XPREFIX}.pc, we need
  86         # to test the OS release package type
  87         # Only doable within a native environment not under SDK
  88         if( OSRELEASE MATCHES "debian" AND NOT DEFINED ENV{SDKTARGETSYSROOT} AND NOT DEFINED CMAKE_TOOLCHAIN_FILE)
  89                 execute_process(
  90                         COMMAND dpkg -S *${XPREFIX}.pc
  91                                         OUTPUT_VARIABLE TMP_PKG_BIN
  92                 )
  93                 #Need to be harden check
  94                 string(REGEX REPLACE ":.*$" "" PKG_BIN ${TMP_PKG_BIN})
  95                 set(DEB_PKG_DEPS "${DEB_PKG_DEPS} ${PKG_BIN} ${DEB_EXTRA_DEP}")
  96         endif()
  97 endforeach()
  98
  99 if(NOT EXISTS ${RPM_TEMPLATE_DIR}/rpm-config.spec.in)
 100         MESSAGE(FATAL_ERROR "${Red}Missing mandatory files: you need rpm-config.spec.in in ${RPM_TEMPLATE_DIR} folder.${ColourReset}")
 101 endif()
 102
 103 # Because the tool "dpkg" is used on the packages db to find the
 104 # package providing the pkg-cong file ${XPREFIX}.pc, we need
 105 # to test the OS release package type
 106 # Only doable within a native environment not under SDK
 107 if(OSRELEASE MATCHES "debian" AND NOT DEFINED ENV{SDKTARGETSYSROOT} AND NOT DEFINED CMAKE_TOOLCHAIN_FILE)
 108         add_custom_target(packaging_deb DEPENDS ${DEB_TEMPLATE_DIR}/debian.compat.in
 109                                 ${DEB_TEMPLATE_DIR}/debian.changelog.in
 110                                 ${DEB_TEMPLATE_DIR}/deb-config.dsc.in
 111                                 ${DEB_TEMPLATE_DIR}/deb-config.install.in
 112                                 ${DEB_TEMPLATE_DIR}/debian.control.in
 113                                 ${DEB_TEMPLATE_DIR}/debian.rules.in
 114                 COMMAND ${CMAKE_COMMAND} -DINFILE=${DEB_TEMPLATE_DIR}/debian.compat.in          -DOUTFILE=${PACKAGING_DEB_OUTPUT_COMPAT}        -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}        -P      ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 115                 COMMAND ${CMAKE_COMMAND} -DINFILE=${DEB_TEMPLATE_DIR}/debian.changelog.in       -DOUTFILE=${PACKAGING_DEB_OUTPUT_CHANGELOG}     -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}        -P      ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 116                 COMMAND ${CMAKE_COMMAND} -DINFILE=${DEB_TEMPLATE_DIR}/deb-config.dsc.in         -DOUTFILE=${PACKAGING_DEB_OUTPUT_DSC}           -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}        -P      ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 117                 COMMAND ${CMAKE_COMMAND} -DINFILE=${DEB_TEMPLATE_DIR}/deb-config.install.in     -DOUTFILE=${PACKAGING_DEB_OUTPUT_INSTALL}       -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}        -P      ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 118                 COMMAND ${CMAKE_COMMAND} -DINFILE=${DEB_TEMPLATE_DIR}/debian.control.in         -DOUTFILE=${PACKAGING_DEB_OUTPUT_CONTROL}       -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}        -P      ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 119                 COMMAND ${CMAKE_COMMAND} -DINFILE=${DEB_TEMPLATE_DIR}/debian.rules.in           -DOUTFILE=${PACKAGING_DEB_OUTPUT_RULES}         -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}        -P      ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 120         )
 121 endif()
 122
 123 add_custom_target(packaging)
 124 set(PACKAGING_SPEC_OUTPUT ${PROJECT_PKG_ENTRY_POINT}/${NPKG_PROJECT_NAME}.spec)
 125 add_custom_target(packaging_rpm DEPENDS ${RPM_TEMPLATE_DIR}/rpm-config.spec.in
 126         COMMAND ${CMAKE_COMMAND} -DINFILE=${RPM_TEMPLATE_DIR}/rpm-config.spec.in -DOUTFILE=${PACKAGING_SPEC_OUTPUT} -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 127 )
 128 add_dependencies(packaging packaging_rpm)
 129 if(TARGET packaging_wgt)
 130         add_dependencies(packaging packaging_wgt)
 131 endif()
 132 if(OSRELEASE MATCHES "debian" AND NOT DEFINED ENV{SDKTARGETSYSROOT} AND NOT DEFINED CMAKE_TOOLCHAIN_FILE)
 133         # Target to add dependencies indirectly to "packaging" target.
 134         add_dependencies(packaging packaging_deb)
 135 endif()
 136
 137 #Generate a cmake cache file usable by cmake script.
 138 set(CacheForScript ${CMAKE_BINARY_DIR}/CMakeCacheForScript.cmake)
 139 #Create a tmp cmake file.
 140 file(WRITE ${CacheForScript} "")
 141
 142 get_cmake_property(Vars VARIABLES)
 143 foreach(Var ${Vars})
 144         if(${Var})
 145                 #Replace unwanted char.
 146                 string(REPLACE "\\" "\\\\" VALUE ${${Var}})
 147                 string(REPLACE "\n" "\\n" VALUE ${VALUE})
 148                 string(REPLACE "\r" "\\n" VALUE ${VALUE})
 149                 string(REPLACE "\"" "\\\"" VALUE ${VALUE})
 150         endif()
 151         file(APPEND ${CacheForScript} "set(${Var} \"${VALUE}\")\n")
 152 endforeach()
 153
 154 # ----------------------------------------------------------------------------
 155 #                                Autobuild target
 156 # ----------------------------------------------------------------------------
 157
 158 add_custom_target(autobuild ALL DEPENDS ${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/autobuild/agl/autobuild.in
 159         ${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/autobuild/linux/autobuild.in
 160         COMMAND ${CMAKE_COMMAND} -DINFILE=${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/autobuild/agl/autobuild.in -DOUTFILE=${PROJECT_TEMPLATE_AGL_AUTOBUILD_DIR}/autobuild -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 161         COMMAND ${CMAKE_COMMAND} -DINFILE=${CMAKE_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/autobuild/agl/autobuild.in -DOUTFILE=${PROJECT_TEMPLATE_LINUX_AUTOBUILD_DIR}/autobuild -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 162 )