cmake/cmake.d/02-variables.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20
  21 #--------------------------------------------------------------------------
  22 #  WARNING:
  23 #     Do not change this cmake template
  24 #     Customise your preferences in "./etc/config.cmake"
  25 #--------------------------------------------------------------------------
  26
  27 # Get colorized message output non Windows OS. You know bash ? :)
  28 if(NOT WIN32)
  29   string(ASCII 27 Esc)
  30   set(ColourReset "${Esc}[m")
  31   set(ColourBold  "${Esc}[1m")
  32   set(Red         "${Esc}[31m")
  33   set(Green       "${Esc}[32m")
  34   set(Yellow      "${Esc}[33m")
  35   set(Blue        "${Esc}[34m")
  36   set(Magenta     "${Esc}[35m")
  37   set(Cyan        "${Esc}[36m")
  38   set(White       "${Esc}[37m")
  39   set(BoldRed     "${Esc}[1;31m")
  40   set(BoldGreen   "${Esc}[1;32m")
  41   set(BoldYellow  "${Esc}[1;33m")
  42   set(BoldBlue    "${Esc}[1;34m")
  43   set(BoldMagenta "${Esc}[1;35m")
  44   set(BoldCyan    "${Esc}[1;36m")
  45   set(BoldWhite   "${Esc}[1;37m")
  46 endif()
  47
  48 # Native packaging name
  49 set(NPKG_PROJECT_NAME agl-${PROJECT_NAME})
  50
  51 # Get the os type
  52 # Used to package .deb
  53 if(EXISTS "/etc/os-release")
  54         execute_process(COMMAND grep -E "^ID(=|_LIKE=)" /etc/os-release
  55                 OUTPUT_VARIABLE TMP_OSRELEASE
  56         )
  57         if (NOT TMP_OSRELEASE STREQUAL "")
  58                 string(REGEX REPLACE ".*=" "" OSRELEASE ${TMP_OSRELEASE})
  59         else()
  60                 set(OSRELEASE "NOT DEBIAN OS")
  61         endif()
  62         message(STATUS "OSRELEASE = ${OSRELEASE}")
  63 else()
  64         set(OSRELEASE "NOT DEBIAN OS")
  65 endif()
  66
  67 if(DEFINED ENV{SDKTARGETSYSROOT})
  68         file(STRINGS $ENV{SDKTARGETSYSROOT}/usr/include/linux/version.h LINUX_VERSION_CODE_LINE REGEX "LINUX_VERSION_CODE")
  69 elseif(DEFINED ENV{PKG_CONFIG_SYSROOT_DIR})
  70         file(STRINGS $ENV{PKG_CONFIG_SYSROOT_DIR}/usr/include/linux/version.h LINUX_VERSION_CODE_LINE REGEX "LINUX_VERSION_CODE")
  71 else()
  72         file(STRINGS /usr/include/linux/version.h LINUX_VERSION_CODE_LINE REGEX "LINUX_VERSION_CODE")
  73 endif()
  74
  75 string(REGEX MATCH "[0-9]+" LINUX_VERSION_CODE ${LINUX_VERSION_CODE_LINE})
  76 math(EXPR a "${LINUX_VERSION_CODE} >> 16")
  77 math(EXPR b "(${LINUX_VERSION_CODE} >> 8) & 255")
  78 math(EXPR c "(${LINUX_VERSION_CODE} & 255)")
  79
  80 set(KERNEL_VERSION "${a}.${b}.${c}")
  81
  82 # Include project configuration
  83 # ------------------------------
  84 project(${PROJECT_NAME} VERSION ${PROJECT_VERSION} LANGUAGES ${PROJECT_LANGUAGES})
  85 set(PROJECT_LIBDIR "${CMAKE_SOURCE_DIR}/libs" CACHE PATH "Subpath to libraries")
  86 set(PROJECT_RESOURCES "${CMAKE_SOURCE_DIR}/data" CACHE PATH "Subpath to data")
  87
  88 set(AFB_TOKEN   ""      CACHE PATH "Default AFB_TOKEN")
  89 set(AFB_REMPORT "1234" CACHE PATH "Default AFB_TOKEN")
  90
  91 # Check GCC minimal version
  92 if (gcc_minimal_version)
  93 message (STATUS "${Cyan}-- Check gcc_minimal_version (found gcc version ${CMAKE_C_COMPILER_VERSION}) \
  94 (found g++ version ${CMAKE_CXX_COMPILER_VERSION})${ColourReset}")
  95 if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version} OR CMAKE_C_COMPILER_VERSION VERSION_LESS ${gcc_minimal_version})
  96 message(FATAL_ERROR "${Red}**** FATAL: Require at least gcc-${gcc_minimal_version} please set CMAKE_C[XX]_COMPILER")
  97 endif()
  98 endif(gcc_minimal_version)
  99
 100 # Check Kernel mandatory version, will fail the configuration if required version not matched.
 101 if (kernel_mandatory_version)
 102 message (STATUS "${Cyan}-- Check kernel_mandatory_version (found kernel version ${KERNEL_VERSION})${ColourReset}")
 103 if (KERNEL_VERSION VERSION_LESS ${kernel_mandatory_version})
 104 message(FATAL_ERROR "${Red}**** FATAL: Require at least ${kernel_mandatory_version} please use a recent kernel or source your SDK environment then clean and reconfigure your CMake project.")
 105 endif (KERNEL_VERSION VERSION_LESS ${kernel_mandatory_version})
 106 endif(kernel_mandatory_version)
 107
 108 # Check Kernel minimal version just print a Warning about missing features
 109 # and set a definition to be used as preprocessor condition in code to disable
 110 # incompatibles features.
 111 if (kernel_minimal_version)
 112 message (STATUS "${Cyan}-- Check kernel_minimal_version (found kernel version ${KERNEL_VERSION})${ColourReset}")
 113 if (KERNEL_VERSION VERSION_LESS ${kernel_minimal_version})
 114 message(WARNING "${Yellow}**** Warning: Some feature(s) require at least ${kernel_minimal_version}. Please use a recent kernel or source your SDK environment then clean and reconfigure your CMake project.${ColourReset}")
 115 else (KERNEL_VERSION VERSION_LESS ${kernel_minimal_version})
 116 add_definitions(-DKERNEL_MINIMAL_VERSION_OK)
 117 endif (KERNEL_VERSION VERSION_LESS ${kernel_minimal_version})
 118 endif(kernel_minimal_version)
 119
 120 # Project path variables
 121 # ----------------------
 122
 123 # If no install dir try to guess some smart default
 124 if(BINDINGS_INSTALL_PREFIX)
 125         set(BINDINGS_INSTALL_DIR ${BINDINGS_INSTALL_PREFIX}/${PROJECT_NAME} CACHE PATH "Where the binding will be installed in your system")
 126 else()
 127         set(BINDINGS_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/${PROJECT_NAME} CACHE PATH "Where the binding will be installed in your system")
 128 endif()
 129
 130 set(PKGOUT_DIR package CACHE PATH "Output directory for packages")
 131
 132 # Define a default package directory
 133 if(PKG_PREFIX)
 134         set(PROJECT_PKG_BUILD_DIR ${PKG_PREFIX}/${PKGOUT_DIR} CACHE PATH "Application contents to be packaged")
 135 else()
 136         set(PROJECT_PKG_BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR}/${PKGOUT_DIR} CACHE PATH "Application contents to be packaged")
 137 endif()
 138
 139 # Paths to templates files
 140 set(TEMPLATE_DIR "${PKG_TEMPLATE_PREFIX}/cmake/template.d" CACHE PATH "Subpath to a directory where are stored needed files to launch on remote target to debuging purposes")
 141
 142 if(NOT WIDGET_CONFIG_TEMPLATE)
 143         set(WIDGET_CONFIG_TEMPLATE ${TEMPLATE_DIR}/config.xml.in CACHE PATH "Path to widget config file template (config.xml.in)")
 144 endif()
 145
 146 string(REGEX REPLACE "^(.*)/.*$" "\\1" ENTRY_POINT "${PKG_TEMPLATE_PREFIX}")
 147 set(PROJECT_PKG_ENTRY_POINT ${ENTRY_POINT}/packaging CACHE PATH "Where package build files, like rpm.spec file or config.xml, are write.")
 148
 149 # Path to autobuild template
 150 set(PROJECT_TEMPLATE_AGL_AUTOBUILD_DIR ${CMAKE_SOURCE_DIR}/conf.d/autobuild/agl CACHE PATH "Subpath to a directory where are stored autobuild script")
 151 set(PROJECT_TEMPLATE_LINUX_AUTOBUILD_DIR ${CMAKE_SOURCE_DIR}/conf.d/autobuild/linux CACHE PATH "Subpath to a directory where are stored autobuild script")
 152
 153 # Archive target variables
 154 set(ARCHIVE_OUTPUT_ARCHIVE ${PROJECT_PKG_ENTRY_POINT}/${NPKG_PROJECT_NAME}_${PROJECT_VERSION}.orig.tar)
 155 set(ARCHIVE_OUTPUT ${ARCHIVE_OUTPUT_ARCHIVE}.gz)
 156 set(TMP_ARCHIVE_SUBMODULE ${PROJECT_PKG_ENTRY_POINT}/${NPKG_PROJECT_NAME}-sub)
 157 set(CMD_ARCHIVE_SUBMODULE \'git archive --verbose --prefix=${NPKG_PROJECT_NAME}-${PROJECT_VERSION}/$$path/ --format tar HEAD --output ${TMP_ARCHIVE_SUBMODULE}-$$sha1.tar\' )
 158
 159 if(OSRELEASE MATCHES "debian" AND NOT DEFINED ENV{SDKTARGETSYSROOT} AND NOT DEFINED CMAKE_TOOLCHAIN_FILE)
 160         # build deb spec file from template
 161         set(PACKAGING_DEB_OUTPUT_DSC       ${PROJECT_PKG_ENTRY_POINT}/${NPKG_PROJECT_NAME}.dsc)
 162         set(PACKAGING_DEB_OUTPUT_INSTALL   ${PROJECT_PKG_ENTRY_POINT}/debian.${NPKG_PROJECT_NAME}.install)
 163         set(PACKAGING_DEB_OUTPUT_CHANGELOG ${PROJECT_PKG_ENTRY_POINT}/debian.changelog)
 164         set(PACKAGING_DEB_OUTPUT_COMPAT    ${PROJECT_PKG_ENTRY_POINT}/debian.compat)
 165         set(PACKAGING_DEB_OUTPUT_CONTROL   ${PROJECT_PKG_ENTRY_POINT}/debian.control)
 166         set(PACKAGING_DEB_OUTPUT_RULES     ${PROJECT_PKG_ENTRY_POINT}/debian.rules)
 167 endif()
 168
 169 # Break After Binding are loaded but before they get initialised
 170 set(GDB_INITIAL_BREAK "personality" CACHE STRING "Initial Break Point for GDB remote")
 171
 172 # Define some checker binaries to verify input DATA files
 173 # to be included in package.
 174 set(LUA_CHECKER "luac" CACHE STRING "LUA compiler")
 175 set(XML_CHECKER "xmllint" CACHE STRING "XML linter")
 176 set(JSON_CHECKER "json_verify" CACHE STRING "JSON linter")