cmake/cmake.d/02-macros.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20 #--------------------------------------------------------------------------
  21 #  WARNING:
  22 #     Do not change this cmake template
  23 #     Customise your preferences in "./conf.d/cmake/config.cmake"
  24 #--------------------------------------------------------------------------
  25 # Generic useful macro
  26 # -----------------------
  27 macro(PROJECT_TARGET_ADD TARGET_NAME)
  28         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
  29         set(TARGET_NAME ${TARGET_NAME})
  30 endmacro(PROJECT_TARGET_ADD)
  31
  32 macro(PROJECT_PKGDEP_ADD PKG_NAME)
  33         set_property(GLOBAL APPEND PROPERTY PROJECT_PKG_DEPS ${PKG_NAME})
  34 endmacro(PROJECT_PKGDEP_ADD)
  35
  36 macro(defstr name value)
  37         add_definitions(-D${name}=${value})
  38 endmacro(defstr)
  39
  40 macro(configure_files_in_dir dir)
  41         file(GLOB filelist "${dir}/*in")
  42         foreach(file ${filelist})
  43                 get_filename_component(filename ${file} NAME)
  44                 string(REGEX REPLACE "target" "${RSYNC_TARGET}" destinationfile ${filename})
  45                 string(REGEX REPLACE ".in$" "" destinationfile ${destinationfile})
  46                 configure_file(${file} ${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile})
  47                 set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile}")
  48         endforeach()
  49 endmacro(configure_files_in_dir)
  50
  51 # Create custom target dedicated for HTML5 and DATA AGL target type
  52 macro(add_input_files INPUT_FILES)
  53         add_custom_target(${TARGET_NAME}
  54         DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
  55         )
  56
  57         add_custom_command(TARGET ${TARGET_NAME}
  58         PRE_BUILD
  59         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  60         COMMAND [ -f *xml ] && ${XML_CHECKER} ${INPUT_FILES}
  61         COMMAND [ -f *lua ] && ${LUA_CHECKER} ${INPUT_FILES}
  62         COMMAND [ -f *json ] && for f in ${INPUT_FILES}; do cat ${INPUT_FILES} | ${JSON_CHECKER}; done
  63         )
  64
  65         add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
  66         DEPENDS  ${INPUT_FILES}
  67         OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
  68         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
  69         COMMAND touch ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
  70         COMMAND cp -r ${INPUT_FILES} ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
  71         )
  72 endmacro()
  73
  74 # Set the name of the OPENAPI definition JSON file for binding v2
  75 macro(set_openapi_filename openapi_filename)
  76         set(OPENAPI_DEF ${openapi_filename} CACHE STRING "OpenAPI JSON file name used to generate binding header file before building a binding v2 target.")
  77 endmacro()
  78
  79 # Pre-packaging
  80 macro(project_targets_populate)
  81         # Default Widget default directory
  82         set(PACKAGE_BINDIR  ${PROJECT_PKG_BUILD_DIR}/bin)
  83         set(PACKAGE_ETCDIR  ${PROJECT_PKG_BUILD_DIR}/etc)
  84         set(PACKAGE_LIBDIR  ${PROJECT_PKG_BUILD_DIR}/lib)
  85         set(PACKAGE_HTTPDIR ${PROJECT_PKG_BUILD_DIR}/htdocs)
  86         set(PACKAGE_DATADIR ${PROJECT_PKG_BUILD_DIR}/data)
  87
  88         add_custom_command(OUTPUT ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR}
  89                 COMMAND mkdir -p ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR})
  90         add_custom_target(populate DEPENDS ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR})
  91                 get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
  92         foreach(TARGET ${PROJECT_TARGETS})
  93                 get_target_property(T ${TARGET} LABELS)
  94                 if(T)
  95                         # Declaration of a custom command that will populate widget tree with the target
  96                         set(POPULE_PACKAGE_TARGET "project_populate_${TARGET}")
  97
  98                         get_target_property(P ${TARGET} PREFIX)
  99                         get_target_property(BD ${TARGET} BINARY_DIR)
 100                         get_target_property(SD ${TARGET} SOURCE_DIR)
 101                         get_target_property(OUT ${TARGET} OUTPUT_NAME)
 102
 103                         if(P MATCHES "NOTFOUND$")
 104                                 if (${T} STREQUAL "BINDING")
 105                                         set(P "lib")
 106                                 else()
 107                                         set(P "")
 108                                 endif()
 109                         endif()
 110
 111                         if(${T} STREQUAL "BINDING")
 112                                 list(APPEND BINDINGS_LIST "${P}${OUT}")
 113                                 add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${OUT}.so
 114                                         DEPENDS ${BD}/${P}${OUT}.so
 115                                         COMMAND mkdir -p ${PACKAGE_LIBDIR}
 116                                         COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
 117                                 )
 118                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${OUT}.so)
 119                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 120                                 add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 121                         elseif(${T} STREQUAL "BINDINGV2")
 122                                 add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${OUT}.so
 123                                         DEPENDS ${BD}/${P}${OUT}.so
 124                                         COMMAND mkdir -p ${PACKAGE_LIBDIR}
 125                                         COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
 126                                 )
 127                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${OUT}.so)
 128
 129                                 if (OPENAPI_DEF)
 130                                         add_custom_command(OUTPUT ${SD}/${OPENAPI_DEF}.h
 131                                                 DEPENDS ${SD}/${OPENAPI_DEF}.json
 132                                                 COMMAND afb-genskel ${SD}/${OPENAPI_DEF}.json > ${SD}/${OPENAPI_DEF}.h
 133                                         )
 134                                         add_custom_target("${TARGET}_GENSKEL" DEPENDS ${SD}/${OPENAPI_DEF}.h
 135                                                 COMMENT "Generating OpenAPI header file ${OPENAPI_DEF}.h")
 136                                         add_dependencies(${TARGET} "${TARGET}_GENSKEL")
 137                                 else()
 138                                         add_custom_command(OUTPUT ${SD}/${OUT}-apidef.h
 139                                                 DEPENDS ${SD}/${OUT}-apidef.json
 140                                                 COMMAND afb-genskel ${SD}/${OUT}-apidef.json > ${SD}/${OUT}-apidef.h
 141                                         )
 142                                         add_custom_target("${TARGET}_GENSKEL" DEPENDS ${SD}/${OUT}-apidef.h
 143                                                 COMMENT "Generating OpenAPI header file ${OUT}-apidef.h")
 144                                         add_dependencies(${TARGET} "${TARGET}_GENSKEL")
 145                                 endif()
 146                         elseif(${T} STREQUAL "EXECUTABLE")
 147                                 add_custom_command(OUTPUT ${PACKAGE_BINDIR}/${P}${OUT}
 148                                         DEPENDS ${BD}/${P}${OUT}
 149                                         COMMAND mkdir -p ${PACKAGE_BINDIR}
 150                                         COMMAND cp ${BD}/${P}${OUT} ${PACKAGE_BINDIR}
 151                                 )
 152                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_BINDIR}/${P}${OUT})
 153                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 154                                 add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 155                         elseif(${T} STREQUAL "HTDOCS")
 156                                 add_custom_command(OUTPUT ${PACKAGE_HTTPDIR}-xx
 157                                         DEPENDS ${BD}/${P}${OUT}
 158                                         COMMAND mkdir -p ${PACKAGE_HTTPDIR}
 159                                         COMMAND touch ${PACKAGE_HTTPDIR}
 160                                         COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_HTTPDIR}
 161                                 )
 162                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_HTTPDIR}-xx)
 163                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 164                                 add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 165                         elseif(${T} STREQUAL "DATA")
 166                                 add_custom_command(OUTPUT ${PACKAGE_DATADIR}-xx
 167                                         DEPENDS ${BD}/${P}${OUT}
 168                                         COMMAND mkdir -p ${PACKAGE_DATADIR}
 169                                         COMMAND touch ${PACKAGE_DATADIR}
 170                                         COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_DATADIR}
 171                                 )
 172                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_DATADIR}-xx)
 173                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 174                                 add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 175                         endif(${T} STREQUAL "BINDING")
 176                 elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 177                         MESSAGE(".. Warning: ${TARGET} ignored when packaging.")
 178                 endif()
 179         endforeach()
 180 endmacro(project_targets_populate)
 181
 182 macro(remote_targets_populate)
 183         if (DEFINED ENV{RSYNC_TARGET})
 184                 set (RSYNC_TARGET $ENV{RSYNC_TARGET})
 185         endif()
 186         if (DEFINED ENV{RSYNC_PREFIX})
 187                 set (RSYNC_PREFIX $ENV{RSYNC_PREFIX})
 188         endif()
 189
 190         set(
 191                 REMOTE_LAUNCH "Test on target with: ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh"
 192                 CACHE STRING "Command to start ${PROJECT_NAME} on remote target ${RSYNC_TARGET}"
 193         )
 194
 195         if(NOT RSYNC_TARGET OR NOT RSYNC_PREFIX)
 196                 message ("${Yellow}.. Warning: RSYNC_TARGET RSYNC_PREFIX not defined 'make remote-target-populate' not instanciated${ColourReset}")
 197                 add_custom_target(remote-target-populate
 198                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make remote-target-populate'${ColourReset}"
 199                         COMMAND exit -1
 200                 )
 201         else()
 202                 set(BINDINGS_REGEX "not_set")
 203                 if(DEFINED BINDINGS_LIST)
 204                         list(LENGTH BINDINGS_LIST BINDINGS_LIST_LENGTH)
 205                         if(BINDINGS_LIST_LENGTH EQUAL 1)
 206                                 list(GET BINDINGS_LIST 0 BINDINGS_REGEX)
 207                                 string(APPEND BINDINGS_REGEX ".so")
 208                         elseif(BINDINGS_LIST_LENGTH GREATER 1)
 209                                 foreach(B IN LISTS BINDINGS_LIST)
 210                                         STRING(APPEND BINDINGS_STR "${B}|")
 211                                 endforeach()
 212                                         STRING(REGEX REPLACE "^(.*)\\|$" "(\\1).so" BINDINGS_REGEX ${BINDINGS_STR})
 213                         endif()
 214                 endif()
 215
 216                 configure_files_in_dir(${TEMPLATE_DIR})
 217                 configure_files_in_dir(${TEMPLATE_DIR})
 218
 219                 add_custom_target(remote-target-populate
 220                         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/*.sh
 221                         COMMAND rsync -e "ssh -o StrictHostKeyChecking=no -o UserKnownHostsFile=/dev/null" --archive --delete ${PROJECT_PKG_BUILD_DIR}/ ${RSYNC_TARGET}:${RSYNC_PREFIX}/${PROJECT_NAME}
 222                         COMMENT "${REMOTE_LAUNCH}"
 223                 )
 224                 add_dependencies(remote-target-populate populate)
 225         endif()
 226 endmacro(remote_targets_populate)
 227
 228 macro(wgt_package_build)
 229         if(NOT EXISTS ${WIDGET_CONFIG_TEMPLATE})
 230                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need a config.xml template: please specify WIDGET_CONFIG_TEMPLATE correctly.${ColourReset}")
 231         endif()
 232         if(NOT WIDGET_TYPE)
 233                 MESSAGE(FATAL_ERROR "WIDGET_TYPE must be set in your config.cmake.\neg.: set(WIDGET_TYPE application/vnd.agl.service)")
 234         endif()
 235         if(NOT DEFINED PROJECT_ICON)
 236                 if( ${WIDGET_TYPE} MATCHES "agl.native")
 237                         set(PROJECT_ICON ${PKG_APP_TEMPLATE_DIR}/wgt/icon-native.png)
 238                 elseif( ${WIDGET_TYPE} MATCHES "agl.service")
 239                         set(PROJECT_ICON ${PKG_APP_TEMPLATE_DIR}/wgt/icon-service.png)
 240                 elseif( ${WIDGET_TYPE} MATCHES "x-executable")
 241                         set(PROJECT_ICON ${PKG_APP_TEMPLATE_DIR}/wgt/icon-qml.png)
 242                 elseif( ${WIDGET_TYPE} MATCHES "text/html")
 243                         set(PROJECT_ICON ${PKG_APP_TEMPLATE_DIR}/wgt/icon-html5.png)
 244                 else()
 245                         set(PROJECT_ICON ${PKG_APP_TEMPLATE_DIR}/wgt/icon-default.png)
 246                 endif()
 247         endif()
 248
 249         if(NOT WIDGET_ENTRY_POINT)
 250                 set(WIDGET_ENTRY_POINT lib)
 251         endif()
 252
 253         add_custom_command(OUTPUT ${PROJECT_PKG_BUILD_DIR}/config.xml
 254                 COMMAND ${CMAKE_COMMAND} -DINFILE=${WIDGET_CONFIG_TEMPLATE} -DOUTFILE=${PROJECT_PKG_BUILD_DIR}/config.xml -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 255                 COMMAND cp ${TEMPLATE_DIR}/icon-default.png ${PROJECT_PKG_BUILD_DIR}/${PROJECT_ICON}
 256
 257         )
 258         add_custom_target(packaging_wgt DEPENDS ${PROJECT_PKG_BUILD_DIR}/config.xml)
 259
 260         # Fulup ??? copy any extra file in wgt/etc into populate package before building the widget
 261         file(GLOB PROJECT_CONF_FILES "${TEMPLATE_DIR}/etc/*")
 262         if(${PROJECT_CONF_FILES})
 263                 file(COPY "${TEMPLATE_DIR}/etc/*" DESTINATION ${PROJECT_PKG_BUILD_DIR}/etc/)
 264         endif(${PROJECT_CONF_FILES})
 265
 266         add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 267                 DEPENDS ${PROJECT_TARGETS}
 268                 COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${PROJECT_PKG_BUILD_DIR}
 269         )
 270
 271         add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 272         add_dependencies(widget populate packaging_wgt)
 273         set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}.wgt")
 274
 275         if(NOT RSYNC_TARGET)
 276                 message ("${Yellow}.. Warning: RSYNC_TARGET not defined 'make widget-target-install' not instanciated${ColourReset}")
 277                 add_custom_target(widget-target-install
 278                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make widget-target-install'${ColourReset}"
 279                         COMMAND exit -1
 280                 )
 281         else()
 282         configure_files_in_dir(${TEMPLATE_DIR})
 283         add_custom_target(widget-target-install
 284         DEPENDS widget
 285         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 286         COMMAND ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 287         )
 288 endif()
 289
 290         if(PACKAGE_MESSAGE)
 291         add_custom_command(TARGET widget
 292                 POST_BUILD
 293                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 294         endif()
 295 endmacro(wgt_package_build)
 296
 297 macro(rpm_package_build)
 298         add_custom_command(OUTPUT ${NPKG_PROJECT_NAME}.spec
 299                 DEPENDS ${PROJECT_TARGETS}
 300                                 archive
 301                                 packaging
 302                 COMMAND rpmbuild --define=\"%_sourcedir ${PROJECT_PKG_ENTRY_POINT}\" -ba  ${PROJECT_PKG_ENTRY_POINT}/${NPKG_PROJECT_NAME}.spec
 303         )
 304
 305         add_custom_target(rpm DEPENDS ${NPKG_PROJECT_NAME}.spec)
 306         add_dependencies(rpm populate packaging)
 307
 308         if(PACKAGE_MESSAGE)
 309         add_custom_command(TARGET rpm
 310                 POST_BUILD
 311                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 312         endif()
 313 endmacro(rpm_package_build)
 314
 315 macro(deb_package_build)
 316 #TODO
 317 endmacro(deb_package_build)
 318
 319 macro(project_package_build)
 320         if(EXISTS ${TEMPLATE_DIR})
 321                 rpm_package_build()
 322         endif()
 323
 324         if(EXISTS ${TEMPLATE_DIR})
 325                 wgt_package_build()
 326         endif()
 327
 328         if(EXISTS ${TEMPLATE_DIR})
 329                 deb_package_build()
 330         endif()
 331 endmacro(project_package_build)
 332
 333 macro(project_subdirs_add)
 334         set (ARGSLIST ${ARGN})
 335         list(LENGTH ARGSLIST ARGSNUM)
 336         if(${ARGSNUM} GREATER 0)
 337                 file(GLOB filelist "${ARGV0}")
 338         else()
 339         file(GLOB filelist "*")
 340         endif()
 341
 342         foreach(filename ${filelist})
 343                 if(EXISTS "${filename}/CMakeLists.txt")
 344                         add_subdirectory(${filename})
 345                 endif(EXISTS "${filename}/CMakeLists.txt")
 346         endforeach()
 347 endmacro(project_subdirs_add)
 348
 349 # Print developer helper message when build is done
 350 # -------------------------------------------------------
 351 macro(project_closing_msg)
 352         get_property(PROJECT_TARGETS_SET GLOBAL PROPERTY PROJECT_TARGETS SET)
 353         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 354         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS_SET})
 355                 add_custom_target(${PROJECT_NAME}_build_done ALL
 356                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 357                 )
 358                  add_dependencies(${PROJECT_NAME}_build_done
 359                         ${DEPENDENCIES_TARGET} ${PROJECT_TARGETS})
 360         endif()
 361 endmacro()