cmake/cmake.d/02-macros.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20 #--------------------------------------------------------------------------
  21 #  WARNING:
  22 #     Do not change this cmake template
  23 #     Customise your preferences in "./etc/config.cmake"
  24 #--------------------------------------------------------------------------
  25 # Generic useful macro
  26 # -----------------------
  27 macro(PROJECT_TARGET_ADD TARGET_NAME)
  28         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
  29         set(TARGET_NAME ${TARGET_NAME})
  30 endmacro(PROJECT_TARGET_ADD)
  31
  32 macro(PROJECT_PKGDEP_ADD PKG_NAME)
  33         set_property(GLOBAL APPEND PROPERTY PROJECT_PKG_DEPS ${PKG_NAME})
  34 endmacro(PROJECT_PKGDEP_ADD)
  35
  36 macro(defstr name value)
  37         add_definitions(-D${name}=${value})
  38 endmacro(defstr)
  39
  40 macro(configure_files_in_dir dir)
  41         file(GLOB filelist "${dir}/*in")
  42         foreach(file ${filelist})
  43                 get_filename_component(filename ${file} NAME)
  44                 string(REGEX REPLACE "target" "${RSYNC_TARGET}" destinationfile ${filename})
  45                 configure_file(${file} ${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile})
  46         endforeach()
  47 endmacro(configure_files_in_dir)
  48
  49 # Pre-packaging
  50 macro(project_targets_populate)
  51         # Default Widget default directory
  52         set(PACKAGE_BINDIR  ${PROJECT_PKG_BUILD_DIR}/bin)
  53         set(PACKAGE_ETCDIR  ${PROJECT_PKG_BUILD_DIR}/etc)
  54         set(PACKAGE_LIBDIR  ${PROJECT_PKG_BUILD_DIR}/lib)
  55         set(PACKAGE_HTTPDIR ${PROJECT_PKG_BUILD_DIR}/htdocs)
  56         set(PACKAGE_DATADIR ${PROJECT_PKG_BUILD_DIR}/data)
  57
  58         add_custom_target(populate)
  59                 get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
  60         foreach(TARGET ${PROJECT_TARGETS})
  61                 get_target_property(T ${TARGET} LABELS)
  62                 if(T)
  63                         # Declaration of a custom command that will populate widget tree with the target
  64                         set(POPULE_PACKAGE_TARGET "project_populate_${TARGET}")
  65
  66                         get_target_property(P ${TARGET} PREFIX)
  67                         get_target_property(BD ${TARGET} BINARY_DIR)
  68                         get_target_property(SD ${TARGET} SOURCE_DIR)
  69                         get_target_property(OUT ${TARGET} OUTPUT_NAME)
  70
  71                         if(P MATCHES "NOTFOUND$")
  72                                 if (${T} STREQUAL "BINDING")
  73                                         set(P "lib")
  74                                 else()
  75                                         set(P "")
  76                                 endif()
  77                         endif()
  78
  79                         if(${T} STREQUAL "BINDING")
  80                                 add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${TARGET}.so
  81                                         DEPENDS ${TARGET}
  82                                         COMMAND mkdir -p ${PACKAGE_LIBDIR}
  83                                         COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
  84                                 )
  85                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${TARGET}.so)
  86                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
  87                         elseif(${T} STREQUAL "EXECUTABLE")
  88                                 add_custom_command(OUTPUT ${PACKAGE_BINDIR}/${P}${TARGET}
  89                                         DEPENDS ${TARGET}
  90                                         COMMAND mkdir -p ${PACKAGE_BINDIR}
  91                                         COMMAND cp ${BD}/${P}${OUT} ${PACKAGE_BINDIR}
  92                                 )
  93                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_BINDIR}/${P}${TARGET})
  94                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
  95                         elseif(${T} STREQUAL "HTDOCS")
  96                                 add_custom_command(OUTPUT ${PACKAGE_HTTPDIR}-xx
  97                                         DEPENDS ${TARGET}
  98                                         COMMAND mkdir -p ${PACKAGE_HTTPDIR}
  99                                         COMMAND touch ${PACKAGE_HTTPDIR}
 100                                         COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_HTTPDIR}
 101                                 )
 102                                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_HTTPDIR}-xx)
 103                                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 104                         elseif(${T} STREQUAL "DATA")
 105                                 add_custom_command(OUTPUT ${PACKAGE_DATADIR}-xx
 106                                         DEPENDS ${TARGET}
 107                                         COMMAND mkdir -p ${PACKAGE_DATADIR}
 108                                         COMMAND touch ${PACKAGE_DATADIR}
 109                                         COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_DATADIR}
 110                                 )
 111                                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_DATADIR}-xx)
 112                                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 113                         endif(${T} STREQUAL "BINDING")
 114                 elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 115                         MESSAGE(".. Warning: ${TARGET} ignored when packaging.")
 116                 endif()
 117         endforeach()
 118 endmacro(project_targets_populate)
 119
 120 macro(remote_targets_populate)
 121         if (DEFINED ENV{RSYNC_TARGET})
 122         set (RSYNC_TARGET $ENV{RSYNC_TARGET})
 123         endif()
 124         if (DEFINED ENV{RSYNC_PREFIX})
 125         set (RSYNC_PREFIX $ENV{RSYNC_PREFIX})
 126         endif()
 127
 128         set(
 129                 REMOTE_LAUNCH "Test on target with: ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh"
 130                 CACHE STRING "Command to start ${PROJECT_NAME} on remote target ${RSYNC_TARGET}"
 131         )
 132
 133         if(NOT RSYNC_TARGET OR NOT RSYNC_PREFIX)
 134                 message ("${Yellow}.. Warning: RSYNC_TARGET RSYNC_PREFIX not defined 'make remote-target-populate' not instanciated${ColourReset}")
 135                 add_custom_target(remote-target-populate
 136                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make remote-target-populate'${ColourReset}"
 137                         COMMAND exit -1
 138                 )
 139         else()
 140
 141                 configure_files_in_dir(${SSH_TEMPLATE_DIR})
 142                 configure_files_in_dir(${GDB_TEMPLATE_DIR})
 143
 144                 add_custom_target(remote-target-populate
 145                         DEPENDS populate
 146                         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/*.sh
 147                         COMMAND rsync -e "ssh -o StrictHostKeyChecking=no -o UserKnownHostsFile=/dev/null" --archive --delete ${PROJECT_PKG_BUILD_DIR}/ ${RSYNC_TARGET}:${RSYNC_PREFIX}/${PROJECT_NAME}
 148                         COMMENT "${REMOTE_LAUNCH}"
 149                 )
 150         endif()
 151 endmacro(remote_targets_populate)
 152
 153 macro(wgt_package_build)
 154         if(NOT EXISTS ${WIDGET_CONFIG_TEMPLATE})
 155                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need a config.xml template: please specify WIDGET_CONFIG_TEMPLATE correctly.${ColourReset}")
 156         endif()
 157         if(NOT EXISTS ${WGT_TEMPLATE_DIR}/icon-default.png)
 158                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need ${PROJECT_ICON} file in ${WGT_TEMPLATE_DIR} folder.${ColourReset}")
 159         endif()
 160     if(NOT WIDGET_TYPE)
 161         MESSAGE(FATAL_ERROR "WIDGET_TYPE must be set in your config.cmake.\neg.: set(WIDGET_TYPE application/vnd.agl.service)")
 162     endif()
 163
 164         if(NOT WIDGET_ENTRY_POINT)
 165                 set(WIDGET_ENTRY_POINT lib)
 166         endif()
 167
 168         add_custom_command(OUTPUT ${PROJECT_PKG_BUILD_DIR}/config.xml
 169                 COMMAND ${CMAKE_COMMAND} -DINFILE=${WIDGET_CONFIG_TEMPLATE} -DOUTFILE=${PROJECT_PKG_BUILD_DIR}/config.xml -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 170                 COMMAND cp ${WGT_TEMPLATE_DIR}/icon-default.png ${PROJECT_PKG_BUILD_DIR}/${PROJECT_ICON}
 171
 172         )
 173         add_custom_target(packaging_wgt DEPENDS ${PROJECT_PKG_BUILD_DIR}/config.xml)
 174
 175         # Fulup ??? copy any extra file in wgt/etc into populate package before building the widget
 176         file(GLOB PROJECT_CONF_FILES "${WGT_TEMPLATE_DIR}/etc/*")
 177         if(${PROJECT_CONF_FILES})
 178                 file(COPY "${WGT_TEMPLATE_DIR}/etc/*" DESTINATION ${PROJECT_PKG_BUILD_DIR}/etc/)
 179         endif(${PROJECT_CONF_FILES})
 180
 181         add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 182                 DEPENDS ${PROJECT_TARGETS}
 183                 COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${PROJECT_PKG_BUILD_DIR}
 184         )
 185
 186         add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 187         add_dependencies(widget populate packaging_wgt)
 188         set(ADDITIONAL_MAKE_CLEAN_FILES, "${PROJECT_NAME}.wgt")
 189
 190         if(NOT RSYNC_TARGET)
 191                 message ("${Yellow}.. Warning: RSYNC_TARGET not defined 'make widget-target-install' not instanciated${ColourReset}")
 192                 add_custom_target(widget-target-install
 193                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make widget-target-install'${ColourReset}"
 194                         COMMAND exit -1
 195                 )
 196         else()
 197         configure_files_in_dir(${WGT_TEMPLATE_DIR})
 198         add_custom_target(widget-target-install
 199         DEPENDS widget
 200         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 201         COMMAND ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 202         )
 203 endif()
 204
 205         if(PACKAGE_MESSAGE)
 206         add_custom_command(TARGET widget
 207                 POST_BUILD
 208                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 209         endif()
 210 endmacro(wgt_package_build)
 211
 212 macro(rpm_package_build)
 213         add_custom_command(OUTPUT ${NPKG_PROJECT_NAME}.spec
 214                 DEPENDS ${PROJECT_TARGETS}
 215                                 archive
 216                                 packaging
 217                 COMMAND rpmbuild --define=\"%_sourcedir ${PROJECT_PKG_ENTRY_POINT}\" -ba  ${PROJECT_PKG_ENTRY_POINT}/${NPKG_PROJECT_NAME}.spec
 218         )
 219
 220         add_custom_target(rpm DEPENDS ${NPKG_PROJECT_NAME}.spec)
 221         add_dependencies(rpm populate packaging)
 222         set(ADDITIONAL_MAKE_CLEAN_FILES, "${PROJECT_NAME}.spec")
 223
 224         if(PACKAGE_MESSAGE)
 225         add_custom_command(TARGET rpm
 226                 POST_BUILD
 227                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 228         endif()
 229 endmacro(rpm_package_build)
 230
 231 macro(deb_package_build)
 232 #TODO
 233 endmacro(deb_package_build)
 234
 235 macro(project_package_build)
 236         if(EXISTS ${RPM_TEMPLATE_DIR})
 237                 rpm_package_build()
 238         endif()
 239
 240         if(EXISTS ${WGT_TEMPLATE_DIR})
 241                 wgt_package_build()
 242         endif()
 243
 244         if(EXISTS ${DEB_TEMPLATE_DIR})
 245                 deb_package_build()
 246         endif()
 247 endmacro(project_package_build)
 248
 249 macro(project_subdirs_add)
 250         set (ARGSLIST ${ARGN})
 251         list(LENGTH ARGSLIST ARGSNUM)
 252         if(${ARGSNUM} GREATER 0)
 253                 file(GLOB filelist "${ARGV0}")
 254         else()
 255         file(GLOB filelist "*")
 256         endif()
 257
 258         foreach(filename ${filelist})
 259                 if(EXISTS "${filename}/CMakeLists.txt")
 260                         add_subdirectory(${filename})
 261                 endif(EXISTS "${filename}/CMakeLists.txt")
 262         endforeach()
 263 endmacro(project_subdirs_add)
 264
 265 # Print developer helper message when build is done
 266 # -------------------------------------------------------
 267 macro(project_closing_msg)
 268         get_property(PROJECT_TARGETS_SET GLOBAL PROPERTY PROJECT_TARGETS SET)
 269         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 270         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS_SET})
 271                 add_custom_target(${PROJECT_NAME}_build_done ALL
 272                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 273                 )
 274                  add_dependencies(${PROJECT_NAME}_build_done
 275                         ${DEPENDENCIES_TARGET} ${PROJECT_TARGETS})
 276         endif()
 277 endmacro()