cmake/cmake.d/02-macros.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20 #--------------------------------------------------------------------------
  21 #  WARNING:
  22 #     Do not change this cmake template
  23 #     Customise your preferences in "./conf.d/cmake/config.cmake"
  24 #--------------------------------------------------------------------------
  25 # Generic useful macro
  26 # -----------------------
  27 macro(PROJECT_TARGET_ADD TARGET_NAME)
  28         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
  29         set(TARGET_NAME ${TARGET_NAME})
  30 endmacro(PROJECT_TARGET_ADD)
  31
  32 macro(PROJECT_PKGDEP_ADD PKG_NAME)
  33         set_property(GLOBAL APPEND PROPERTY PROJECT_PKG_DEPS ${PKG_NAME})
  34 endmacro(PROJECT_PKGDEP_ADD)
  35
  36 macro(defstr name value)
  37         add_definitions(-D${name}=${value})
  38 endmacro(defstr)
  39
  40 macro(configure_files_in_dir dir)
  41         file(GLOB filelist "${dir}/*in")
  42         foreach(file ${filelist})
  43                 get_filename_component(filename ${file} NAME)
  44                 string(REGEX REPLACE "target" "${RSYNC_TARGET}" destinationfile ${filename})
  45                 string(REGEX REPLACE ".in$" "" destinationfile ${destinationfile})
  46                 configure_file(${file} ${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile})
  47                 set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile}")
  48         endforeach()
  49 endmacro(configure_files_in_dir)
  50
  51 # Pre-packaging
  52 macro(project_targets_populate)
  53         # Default Widget default directory
  54         set(PACKAGE_BINDIR  ${PROJECT_PKG_BUILD_DIR}/bin)
  55         set(PACKAGE_ETCDIR  ${PROJECT_PKG_BUILD_DIR}/etc)
  56         set(PACKAGE_LIBDIR  ${PROJECT_PKG_BUILD_DIR}/lib)
  57         set(PACKAGE_HTTPDIR ${PROJECT_PKG_BUILD_DIR}/htdocs)
  58         set(PACKAGE_DATADIR ${PROJECT_PKG_BUILD_DIR}/data)
  59
  60         add_custom_target(populate)
  61                 get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
  62         foreach(TARGET ${PROJECT_TARGETS})
  63                 get_target_property(T ${TARGET} LABELS)
  64                 if(T)
  65                         # Declaration of a custom command that will populate widget tree with the target
  66                         set(POPULE_PACKAGE_TARGET "project_populate_${TARGET}")
  67
  68                         get_target_property(P ${TARGET} PREFIX)
  69                         get_target_property(BD ${TARGET} BINARY_DIR)
  70                         get_target_property(SD ${TARGET} SOURCE_DIR)
  71                         get_target_property(OUT ${TARGET} OUTPUT_NAME)
  72
  73                         if(P MATCHES "NOTFOUND$")
  74                                 if (${T} STREQUAL "BINDING")
  75                                         set(P "lib")
  76                                 else()
  77                                         set(P "")
  78                                 endif()
  79                         endif()
  80
  81                         if(${T} STREQUAL "BINDING")
  82                                 list(APPEND BINDINGS_LIST "${P}${OUT}")
  83                                 add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${OUT}.so
  84                                         COMMAND mkdir -p ${PACKAGE_LIBDIR}
  85                                         COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
  86                                 )
  87                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${TARGET}.so)
  88                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET} ${TARGET})
  89                         elseif(${T} STREQUAL "EXECUTABLE")
  90                                 add_custom_command(OUTPUT ${PACKAGE_BINDIR}/${P}${OUT}
  91                                         COMMAND mkdir -p ${PACKAGE_BINDIR}
  92                                         COMMAND cp ${BD}/${P}${OUT} ${PACKAGE_BINDIR}
  93                                 )
  94                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_BINDIR}/${P}${TARGET})
  95                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET} ${TARGET})
  96                         elseif(${T} STREQUAL "HTDOCS")
  97                                 add_custom_command(OUTPUT ${PACKAGE_HTTPDIR}-xx
  98                                         COMMAND mkdir -p ${PACKAGE_HTTPDIR}
  99                                         COMMAND touch ${PACKAGE_HTTPDIR}
 100                                         COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_HTTPDIR}
 101                                 )
 102                                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_HTTPDIR}-xx)
 103                                         add_dependencies(populate ${POPULE_PACKAGE_TARGET} ${TARGET})
 104                         elseif(${T} STREQUAL "DATA")
 105                                 add_custom_command(OUTPUT ${PACKAGE_DATADIR}-xx
 106                                         COMMAND mkdir -p ${PACKAGE_DATADIR}
 107                                         COMMAND touch ${PACKAGE_DATADIR}
 108                                         COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_DATADIR}
 109                                 )
 110                                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_DATADIR}-xx)
 111                                         add_dependencies(populate ${POPULE_PACKAGE_TARGET} ${TARGET})
 112                         endif(${T} STREQUAL "BINDING")
 113                 elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 114                         MESSAGE(".. Warning: ${TARGET} ignored when packaging.")
 115                 endif()
 116         endforeach()
 117 endmacro(project_targets_populate)
 118
 119 macro(remote_targets_populate)
 120         if (DEFINED ENV{RSYNC_TARGET})
 121                 set (RSYNC_TARGET $ENV{RSYNC_TARGET})
 122         endif()
 123         if (DEFINED ENV{RSYNC_PREFIX})
 124                 set (RSYNC_PREFIX $ENV{RSYNC_PREFIX})
 125         endif()
 126
 127         set(
 128                 REMOTE_LAUNCH "Test on target with: ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh"
 129                 CACHE STRING "Command to start ${PROJECT_NAME} on remote target ${RSYNC_TARGET}"
 130         )
 131
 132         if(NOT RSYNC_TARGET OR NOT RSYNC_PREFIX)
 133                 message ("${Yellow}.. Warning: RSYNC_TARGET RSYNC_PREFIX not defined 'make remote-target-populate' not instanciated${ColourReset}")
 134                 add_custom_target(remote-target-populate
 135                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make remote-target-populate'${ColourReset}"
 136                         COMMAND exit -1
 137                 )
 138         else()
 139                 set(BINDINGS_REGEX "not_set")
 140                 if(DEFINED BINDINGS_LIST)
 141                         list(LENGTH BINDINGS_LIST BINDINGS_LIST_LENGTH)
 142                         if(BINDINGS_LIST_LENGTH EQUAL 1)
 143                                 list(GET BINDINGS_LIST 0 BINDINGS_REGEX)
 144                                 string(APPEND BINDINGS_REGEX ".so")
 145                         elseif(BINDINGS_LIST_LENGTH GREATER 1)
 146                                 foreach(B IN LISTS BINDINGS_LIST)
 147                                         STRING(APPEND BINDINGS_STR "${B}|")
 148                                 endforeach()
 149                                         STRING(REGEX REPLACE "^(.*)\\|$" "(\\1).so" BINDINGS_REGEX ${BINDINGS_STR})
 150                         endif()
 151                 endif()
 152
 153                 configure_files_in_dir(${SSH_TEMPLATE_DIR})
 154                 configure_files_in_dir(${GDB_TEMPLATE_DIR})
 155
 156                 add_custom_target(remote-target-populate
 157                         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/*.sh
 158                         COMMAND rsync -e "ssh -o StrictHostKeyChecking=no -o UserKnownHostsFile=/dev/null" --archive --delete ${PROJECT_PKG_BUILD_DIR}/ ${RSYNC_TARGET}:${RSYNC_PREFIX}/${PROJECT_NAME}
 159                         COMMENT "${REMOTE_LAUNCH}"
 160                 )
 161                 add_dependencies(remote-target-populate populate)
 162         endif()
 163 endmacro(remote_targets_populate)
 164
 165 macro(wgt_package_build)
 166         if(NOT EXISTS ${WIDGET_CONFIG_TEMPLATE})
 167                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need a config.xml template: please specify WIDGET_CONFIG_TEMPLATE correctly.${ColourReset}")
 168         endif()
 169         if(NOT EXISTS ${WGT_TEMPLATE_DIR}/icon-default.png)
 170                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need ${PROJECT_ICON} file in ${WGT_TEMPLATE_DIR} folder.${ColourReset}")
 171         endif()
 172     if(NOT WIDGET_TYPE)
 173         MESSAGE(FATAL_ERROR "WIDGET_TYPE must be set in your config.cmake.\neg.: set(WIDGET_TYPE application/vnd.agl.service)")
 174     endif()
 175
 176         if(NOT WIDGET_ENTRY_POINT)
 177                 set(WIDGET_ENTRY_POINT lib)
 178         endif()
 179
 180         add_custom_command(OUTPUT ${PROJECT_PKG_BUILD_DIR}/config.xml
 181                 COMMAND ${CMAKE_COMMAND} -DINFILE=${WIDGET_CONFIG_TEMPLATE} -DOUTFILE=${PROJECT_PKG_BUILD_DIR}/config.xml -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 182                 COMMAND cp ${WGT_TEMPLATE_DIR}/icon-default.png ${PROJECT_PKG_BUILD_DIR}/${PROJECT_ICON}
 183
 184         )
 185         add_custom_target(packaging_wgt DEPENDS ${PROJECT_PKG_BUILD_DIR}/config.xml)
 186
 187         # Fulup ??? copy any extra file in wgt/etc into populate package before building the widget
 188         file(GLOB PROJECT_CONF_FILES "${WGT_TEMPLATE_DIR}/etc/*")
 189         if(${PROJECT_CONF_FILES})
 190                 file(COPY "${WGT_TEMPLATE_DIR}/etc/*" DESTINATION ${PROJECT_PKG_BUILD_DIR}/etc/)
 191         endif(${PROJECT_CONF_FILES})
 192
 193         add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 194                 DEPENDS ${PROJECT_TARGETS}
 195                 COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${PROJECT_PKG_BUILD_DIR}
 196         )
 197
 198         add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 199         add_dependencies(widget populate packaging_wgt)
 200         set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}.wgt")
 201
 202         if(NOT RSYNC_TARGET)
 203                 message ("${Yellow}.. Warning: RSYNC_TARGET not defined 'make widget-target-install' not instanciated${ColourReset}")
 204                 add_custom_target(widget-target-install
 205                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make widget-target-install'${ColourReset}"
 206                         COMMAND exit -1
 207                 )
 208         else()
 209         configure_files_in_dir(${WGT_TEMPLATE_DIR})
 210         add_custom_target(widget-target-install
 211         DEPENDS widget
 212         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 213         COMMAND ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 214         )
 215 endif()
 216
 217         if(PACKAGE_MESSAGE)
 218         add_custom_command(TARGET widget
 219                 POST_BUILD
 220                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 221         endif()
 222 endmacro(wgt_package_build)
 223
 224 macro(rpm_package_build)
 225         add_custom_command(OUTPUT ${NPKG_PROJECT_NAME}.spec
 226                 DEPENDS ${PROJECT_TARGETS}
 227                                 archive
 228                                 packaging
 229                 COMMAND rpmbuild --define=\"%_sourcedir ${PROJECT_PKG_ENTRY_POINT}\" -ba  ${PROJECT_PKG_ENTRY_POINT}/${NPKG_PROJECT_NAME}.spec
 230         )
 231
 232         add_custom_target(rpm DEPENDS ${NPKG_PROJECT_NAME}.spec)
 233         add_dependencies(rpm populate packaging)
 234
 235         if(PACKAGE_MESSAGE)
 236         add_custom_command(TARGET rpm
 237                 POST_BUILD
 238                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 239         endif()
 240 endmacro(rpm_package_build)
 241
 242 macro(deb_package_build)
 243 #TODO
 244 endmacro(deb_package_build)
 245
 246 macro(project_package_build)
 247         if(EXISTS ${RPM_TEMPLATE_DIR})
 248                 rpm_package_build()
 249         endif()
 250
 251         if(EXISTS ${WGT_TEMPLATE_DIR})
 252                 wgt_package_build()
 253         endif()
 254
 255         if(EXISTS ${DEB_TEMPLATE_DIR})
 256                 deb_package_build()
 257         endif()
 258 endmacro(project_package_build)
 259
 260 macro(project_subdirs_add)
 261         set (ARGSLIST ${ARGN})
 262         list(LENGTH ARGSLIST ARGSNUM)
 263         if(${ARGSNUM} GREATER 0)
 264                 file(GLOB filelist "${ARGV0}")
 265         else()
 266         file(GLOB filelist "*")
 267         endif()
 268
 269         foreach(filename ${filelist})
 270                 if(EXISTS "${filename}/CMakeLists.txt")
 271                         add_subdirectory(${filename})
 272                 endif(EXISTS "${filename}/CMakeLists.txt")
 273         endforeach()
 274 endmacro(project_subdirs_add)
 275
 276 # Print developer helper message when build is done
 277 # -------------------------------------------------------
 278 macro(project_closing_msg)
 279         get_property(PROJECT_TARGETS_SET GLOBAL PROPERTY PROJECT_TARGETS SET)
 280         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 281         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS_SET})
 282                 add_custom_target(${PROJECT_NAME}_build_done ALL
 283                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 284                 )
 285                  add_dependencies(${PROJECT_NAME}_build_done
 286                         ${DEPENDENCIES_TARGET} ${PROJECT_TARGETS})
 287         endif()
 288 endmacro()