cmake/cmake.d/02-macros.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20 #--------------------------------------------------------------------------
  21 #  WARNING:
  22 #     Do not change this cmake template
  23 #     Customise your preferences in "./conf.d/cmake/config.cmake"
  24 #--------------------------------------------------------------------------
  25 # Generic useful macro
  26 # -----------------------
  27 macro(PROJECT_TARGET_ADD TARGET_NAME)
  28         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
  29         set(TARGET_NAME ${TARGET_NAME})
  30 endmacro(PROJECT_TARGET_ADD)
  31
  32 macro(PROJECT_PKGDEP_ADD PKG_NAME)
  33         set_property(GLOBAL APPEND PROPERTY PROJECT_PKG_DEPS ${PKG_NAME})
  34 endmacro(PROJECT_PKGDEP_ADD)
  35
  36 macro(defstr name value)
  37         add_definitions(-D${name}=${value})
  38 endmacro(defstr)
  39
  40 macro(configure_files_in_dir dir)
  41         file(GLOB filelist "${dir}/*in")
  42         foreach(file ${filelist})
  43                 get_filename_component(filename ${file} NAME)
  44                 string(REGEX REPLACE "target" "${RSYNC_TARGET}" destinationfile ${filename})
  45                 string(REGEX REPLACE ".in$" "" destinationfile ${destinationfile})
  46                 configure_file(${file} ${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile})
  47                 set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile}")
  48         endforeach()
  49 endmacro(configure_files_in_dir)
  50
  51 # Pre-packaging
  52 macro(project_targets_populate)
  53         # Default Widget default directory
  54         set(PACKAGE_BINDIR  ${PROJECT_PKG_BUILD_DIR}/bin)
  55         set(PACKAGE_ETCDIR  ${PROJECT_PKG_BUILD_DIR}/etc)
  56         set(PACKAGE_LIBDIR  ${PROJECT_PKG_BUILD_DIR}/lib)
  57         set(PACKAGE_HTTPDIR ${PROJECT_PKG_BUILD_DIR}/htdocs)
  58         set(PACKAGE_DATADIR ${PROJECT_PKG_BUILD_DIR}/data)
  59
  60         add_custom_command(OUTPUT ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR}
  61                 COMMAND mkdir -p ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR})
  62         add_custom_target(populate DEPENDS ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR})
  63                 get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
  64         foreach(TARGET ${PROJECT_TARGETS})
  65                 get_target_property(T ${TARGET} LABELS)
  66                 if(T)
  67                         # Declaration of a custom command that will populate widget tree with the target
  68                         set(POPULE_PACKAGE_TARGET "project_populate_${TARGET}")
  69
  70                         get_target_property(P ${TARGET} PREFIX)
  71                         get_target_property(BD ${TARGET} BINARY_DIR)
  72                         get_target_property(SD ${TARGET} SOURCE_DIR)
  73                         get_target_property(OUT ${TARGET} OUTPUT_NAME)
  74
  75                         if(P MATCHES "NOTFOUND$")
  76                                 if (${T} STREQUAL "BINDING")
  77                                         set(P "lib")
  78                                 else()
  79                                         set(P "")
  80                                 endif()
  81                         endif()
  82
  83                         if(${T} STREQUAL "BINDING")
  84                                 list(APPEND BINDINGS_LIST "${P}${OUT}")
  85                                 add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${OUT}.so
  86                                         DEPENDS ${BD}/${P}${OUT}.so
  87                                         COMMAND mkdir -p ${PACKAGE_LIBDIR}
  88                                         COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
  89                                 )
  90                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${OUT}.so)
  91                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
  92                                 add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
  93                         elseif(${T} STREQUAL "BINDINGV2")
  94                                 add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${OUT}.so
  95                                         DEPENDS ${BD}/${P}${OUT}.so
  96                                         COMMAND mkdir -p ${PACKAGE_LIBDIR}
  97                                         COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
  98                                 )
  99                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${OUT}.so)
 100
 101                                 add_custom_command(OUTPUT ${SD}/${P}${OUT}.h
 102                                         DEPENDS ${SD}/${P}${OUT}.json
 103                                         COMMAND afb-genskel ${SD}/${P}${OUT}.json > ${SD}/${P}${OUT}.h
 104                                 )
 105                                 add_custom_target("${TARGET}_GENSKEL" DEPENDS ${SD}/${P}${OUT}.h)
 106                                 add_dependencies(${TARGET} "${TARGET}_GENSKEL")
 107                         elseif(${T} STREQUAL "EXECUTABLE")
 108                                 add_custom_command(OUTPUT ${PACKAGE_BINDIR}/${P}${OUT}
 109                                         DEPENDS ${BD}/${P}${OUT}
 110                                         COMMAND mkdir -p ${PACKAGE_BINDIR}
 111                                         COMMAND cp ${BD}/${P}${OUT} ${PACKAGE_BINDIR}
 112                                 )
 113                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_BINDIR}/${P}${OUT})
 114                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 115                                 add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 116                         elseif(${T} STREQUAL "HTDOCS")
 117                                 add_custom_command(OUTPUT ${PACKAGE_HTTPDIR}-xx
 118                                         DEPENDS ${BD}/${P}${OUT}
 119                                         COMMAND mkdir -p ${PACKAGE_HTTPDIR}
 120                                         COMMAND touch ${PACKAGE_HTTPDIR}
 121                                         COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_HTTPDIR}
 122                                 )
 123                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_HTTPDIR}-xx)
 124                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 125                                 add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 126                         elseif(${T} STREQUAL "DATA")
 127                                 add_custom_command(OUTPUT ${PACKAGE_DATADIR}-xx
 128                                         DEPENDS ${BD}/${P}${OUT}
 129                                         COMMAND mkdir -p ${PACKAGE_DATADIR}
 130                                         COMMAND touch ${PACKAGE_DATADIR}
 131                                         COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_DATADIR}
 132                                 )
 133                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_DATADIR}-xx)
 134                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 135                                 add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 136                         endif(${T} STREQUAL "BINDING")
 137                 elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 138                         MESSAGE(".. Warning: ${TARGET} ignored when packaging.")
 139                 endif()
 140         endforeach()
 141 endmacro(project_targets_populate)
 142
 143 macro(remote_targets_populate)
 144         if (DEFINED ENV{RSYNC_TARGET})
 145                 set (RSYNC_TARGET $ENV{RSYNC_TARGET})
 146         endif()
 147         if (DEFINED ENV{RSYNC_PREFIX})
 148                 set (RSYNC_PREFIX $ENV{RSYNC_PREFIX})
 149         endif()
 150
 151         set(
 152                 REMOTE_LAUNCH "Test on target with: ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh"
 153                 CACHE STRING "Command to start ${PROJECT_NAME} on remote target ${RSYNC_TARGET}"
 154         )
 155
 156         if(NOT RSYNC_TARGET OR NOT RSYNC_PREFIX)
 157                 message ("${Yellow}.. Warning: RSYNC_TARGET RSYNC_PREFIX not defined 'make remote-target-populate' not instanciated${ColourReset}")
 158                 add_custom_target(remote-target-populate
 159                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make remote-target-populate'${ColourReset}"
 160                         COMMAND exit -1
 161                 )
 162         else()
 163                 set(BINDINGS_REGEX "not_set")
 164                 if(DEFINED BINDINGS_LIST)
 165                         list(LENGTH BINDINGS_LIST BINDINGS_LIST_LENGTH)
 166                         if(BINDINGS_LIST_LENGTH EQUAL 1)
 167                                 list(GET BINDINGS_LIST 0 BINDINGS_REGEX)
 168                                 string(APPEND BINDINGS_REGEX ".so")
 169                         elseif(BINDINGS_LIST_LENGTH GREATER 1)
 170                                 foreach(B IN LISTS BINDINGS_LIST)
 171                                         STRING(APPEND BINDINGS_STR "${B}|")
 172                                 endforeach()
 173                                         STRING(REGEX REPLACE "^(.*)\\|$" "(\\1).so" BINDINGS_REGEX ${BINDINGS_STR})
 174                         endif()
 175                 endif()
 176
 177                 configure_files_in_dir(${SSH_TEMPLATE_DIR})
 178                 configure_files_in_dir(${GDB_TEMPLATE_DIR})
 179
 180                 add_custom_target(remote-target-populate
 181                         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/*.sh
 182                         COMMAND rsync -e "ssh -o StrictHostKeyChecking=no -o UserKnownHostsFile=/dev/null" --archive --delete ${PROJECT_PKG_BUILD_DIR}/ ${RSYNC_TARGET}:${RSYNC_PREFIX}/${PROJECT_NAME}
 183                         COMMENT "${REMOTE_LAUNCH}"
 184                 )
 185                 add_dependencies(remote-target-populate populate)
 186         endif()
 187 endmacro(remote_targets_populate)
 188
 189 macro(wgt_package_build)
 190         if(NOT EXISTS ${WIDGET_CONFIG_TEMPLATE})
 191                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need a config.xml template: please specify WIDGET_CONFIG_TEMPLATE correctly.${ColourReset}")
 192         endif()
 193         if(NOT EXISTS ${WGT_TEMPLATE_DIR}/icon-default.png)
 194                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need ${PROJECT_ICON} file in ${WGT_TEMPLATE_DIR} folder.${ColourReset}")
 195         endif()
 196     if(NOT WIDGET_TYPE)
 197         MESSAGE(FATAL_ERROR "WIDGET_TYPE must be set in your config.cmake.\neg.: set(WIDGET_TYPE application/vnd.agl.service)")
 198     endif()
 199
 200         if(NOT WIDGET_ENTRY_POINT)
 201                 set(WIDGET_ENTRY_POINT lib)
 202         endif()
 203
 204         add_custom_command(OUTPUT ${PROJECT_PKG_BUILD_DIR}/config.xml
 205                 COMMAND ${CMAKE_COMMAND} -DINFILE=${WIDGET_CONFIG_TEMPLATE} -DOUTFILE=${PROJECT_PKG_BUILD_DIR}/config.xml -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 206                 COMMAND cp ${WGT_TEMPLATE_DIR}/icon-default.png ${PROJECT_PKG_BUILD_DIR}/${PROJECT_ICON}
 207
 208         )
 209         add_custom_target(packaging_wgt DEPENDS ${PROJECT_PKG_BUILD_DIR}/config.xml)
 210
 211         # Fulup ??? copy any extra file in wgt/etc into populate package before building the widget
 212         file(GLOB PROJECT_CONF_FILES "${WGT_TEMPLATE_DIR}/etc/*")
 213         if(${PROJECT_CONF_FILES})
 214                 file(COPY "${WGT_TEMPLATE_DIR}/etc/*" DESTINATION ${PROJECT_PKG_BUILD_DIR}/etc/)
 215         endif(${PROJECT_CONF_FILES})
 216
 217         add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 218                 DEPENDS ${PROJECT_TARGETS}
 219                 COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${PROJECT_PKG_BUILD_DIR}
 220         )
 221
 222         add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 223         add_dependencies(widget populate packaging_wgt)
 224         set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}.wgt")
 225
 226         if(NOT RSYNC_TARGET)
 227                 message ("${Yellow}.. Warning: RSYNC_TARGET not defined 'make widget-target-install' not instanciated${ColourReset}")
 228                 add_custom_target(widget-target-install
 229                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make widget-target-install'${ColourReset}"
 230                         COMMAND exit -1
 231                 )
 232         else()
 233         configure_files_in_dir(${WGT_TEMPLATE_DIR})
 234         add_custom_target(widget-target-install
 235         DEPENDS widget
 236         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 237         COMMAND ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 238         )
 239 endif()
 240
 241         if(PACKAGE_MESSAGE)
 242         add_custom_command(TARGET widget
 243                 POST_BUILD
 244                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 245         endif()
 246 endmacro(wgt_package_build)
 247
 248 macro(rpm_package_build)
 249         add_custom_command(OUTPUT ${NPKG_PROJECT_NAME}.spec
 250                 DEPENDS ${PROJECT_TARGETS}
 251                                 archive
 252                                 packaging
 253                 COMMAND rpmbuild --define=\"%_sourcedir ${PROJECT_PKG_ENTRY_POINT}\" -ba  ${PROJECT_PKG_ENTRY_POINT}/${NPKG_PROJECT_NAME}.spec
 254         )
 255
 256         add_custom_target(rpm DEPENDS ${NPKG_PROJECT_NAME}.spec)
 257         add_dependencies(rpm populate packaging)
 258
 259         if(PACKAGE_MESSAGE)
 260         add_custom_command(TARGET rpm
 261                 POST_BUILD
 262                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 263         endif()
 264 endmacro(rpm_package_build)
 265
 266 macro(deb_package_build)
 267 #TODO
 268 endmacro(deb_package_build)
 269
 270 macro(project_package_build)
 271         if(EXISTS ${RPM_TEMPLATE_DIR})
 272                 rpm_package_build()
 273         endif()
 274
 275         if(EXISTS ${WGT_TEMPLATE_DIR})
 276                 wgt_package_build()
 277         endif()
 278
 279         if(EXISTS ${DEB_TEMPLATE_DIR})
 280                 deb_package_build()
 281         endif()
 282 endmacro(project_package_build)
 283
 284 macro(project_subdirs_add)
 285         set (ARGSLIST ${ARGN})
 286         list(LENGTH ARGSLIST ARGSNUM)
 287         if(${ARGSNUM} GREATER 0)
 288                 file(GLOB filelist "${ARGV0}")
 289         else()
 290         file(GLOB filelist "*")
 291         endif()
 292
 293         foreach(filename ${filelist})
 294                 if(EXISTS "${filename}/CMakeLists.txt")
 295                         add_subdirectory(${filename})
 296                 endif(EXISTS "${filename}/CMakeLists.txt")
 297         endforeach()
 298 endmacro(project_subdirs_add)
 299
 300 # Print developer helper message when build is done
 301 # -------------------------------------------------------
 302 macro(project_closing_msg)
 303         get_property(PROJECT_TARGETS_SET GLOBAL PROPERTY PROJECT_TARGETS SET)
 304         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 305         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS_SET})
 306                 add_custom_target(${PROJECT_NAME}_build_done ALL
 307                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 308                 )
 309                  add_dependencies(${PROJECT_NAME}_build_done
 310                         ${DEPENDENCIES_TARGET} ${PROJECT_TARGETS})
 311         endif()
 312 endmacro()