cmake/cmake.d/02-macros.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20 #--------------------------------------------------------------------------
  21 #  WARNING:
  22 #     Do not change this cmake template
  23 #     Customise your preferences in "./conf.d/cmake/config.cmake"
  24 #--------------------------------------------------------------------------
  25 # Generic useful macro
  26 # -----------------------
  27 macro(PROJECT_TARGET_ADD TARGET_NAME)
  28         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
  29         set(TARGET_NAME ${TARGET_NAME})
  30 endmacro(PROJECT_TARGET_ADD)
  31
  32 macro(PROJECT_PKGDEP_ADD PKG_NAME)
  33         set_property(GLOBAL APPEND PROPERTY PROJECT_PKG_DEPS ${PKG_NAME})
  34 endmacro(PROJECT_PKGDEP_ADD)
  35
  36 macro(defstr name value)
  37         add_definitions(-D${name}=${value})
  38 endmacro(defstr)
  39
  40 macro(configure_files_in_dir dir)
  41         file(GLOB filelist "${dir}/*in")
  42         foreach(file ${filelist})
  43                 get_filename_component(filename ${file} NAME)
  44                 string(REGEX REPLACE "target" "${RSYNC_TARGET}" destinationfile ${filename})
  45                 string(REGEX REPLACE ".in$" "" destinationfile ${destinationfile})
  46                 configure_file(${file} ${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile})
  47                 set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile}")
  48         endforeach()
  49 endmacro(configure_files_in_dir)
  50
  51 # Pre-packaging
  52 macro(project_targets_populate)
  53         # Default Widget default directory
  54         set(PACKAGE_BINDIR  ${PROJECT_PKG_BUILD_DIR}/bin)
  55         set(PACKAGE_ETCDIR  ${PROJECT_PKG_BUILD_DIR}/etc)
  56         set(PACKAGE_LIBDIR  ${PROJECT_PKG_BUILD_DIR}/lib)
  57         set(PACKAGE_HTTPDIR ${PROJECT_PKG_BUILD_DIR}/htdocs)
  58         set(PACKAGE_DATADIR ${PROJECT_PKG_BUILD_DIR}/data)
  59
  60         add_custom_command(OUTPUT ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR}
  61                 COMMAND mkdir -p ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR})
  62         add_custom_target(populate DEPENDS ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR})
  63                 get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
  64         foreach(TARGET ${PROJECT_TARGETS})
  65                 get_target_property(T ${TARGET} LABELS)
  66                 if(T)
  67                         # Declaration of a custom command that will populate widget tree with the target
  68                         set(POPULE_PACKAGE_TARGET "project_populate_${TARGET}")
  69
  70                         get_target_property(P ${TARGET} PREFIX)
  71                         get_target_property(BD ${TARGET} BINARY_DIR)
  72                         get_target_property(SD ${TARGET} SOURCE_DIR)
  73                         get_target_property(OUT ${TARGET} OUTPUT_NAME)
  74
  75                         if(P MATCHES "NOTFOUND$")
  76                                 if (${T} STREQUAL "BINDING")
  77                                         set(P "lib")
  78                                 else()
  79                                         set(P "")
  80                                 endif()
  81                         endif()
  82
  83                         if(${T} STREQUAL "BINDING")
  84                                 list(APPEND BINDINGS_LIST "${P}${OUT}")
  85                                 add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${OUT}.so
  86                                         COMMAND mkdir -p ${PACKAGE_LIBDIR}
  87                                         COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
  88                                 )
  89                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${TARGET}.so)
  90                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET} ${TARGET})
  91                         elseif(${T} STREQUAL "EXECUTABLE")
  92                                 add_custom_command(OUTPUT ${PACKAGE_BINDIR}/${P}${OUT}
  93                                         COMMAND mkdir -p ${PACKAGE_BINDIR}
  94                                         COMMAND cp ${BD}/${P}${OUT} ${PACKAGE_BINDIR}
  95                                 )
  96                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_BINDIR}/${P}${TARGET})
  97                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET} ${TARGET})
  98                         elseif(${T} STREQUAL "HTDOCS")
  99                                 add_custom_command(OUTPUT ${PACKAGE_HTTPDIR}-xx
 100                                         COMMAND mkdir -p ${PACKAGE_HTTPDIR}
 101                                         COMMAND touch ${PACKAGE_HTTPDIR}
 102                                         COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_HTTPDIR}
 103                                 )
 104                                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_HTTPDIR}-xx)
 105                                         add_dependencies(populate ${POPULE_PACKAGE_TARGET} ${TARGET})
 106                         elseif(${T} STREQUAL "DATA")
 107                                 add_custom_command(OUTPUT ${PACKAGE_DATADIR}-xx
 108                                         COMMAND mkdir -p ${PACKAGE_DATADIR}
 109                                         COMMAND touch ${PACKAGE_DATADIR}
 110                                         COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_DATADIR}
 111                                 )
 112                                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_DATADIR}-xx)
 113                                         add_dependencies(populate ${POPULE_PACKAGE_TARGET} ${TARGET})
 114                         endif(${T} STREQUAL "BINDING")
 115                 elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 116                         MESSAGE(".. Warning: ${TARGET} ignored when packaging.")
 117                 endif()
 118         endforeach()
 119 endmacro(project_targets_populate)
 120
 121 macro(remote_targets_populate)
 122         if (DEFINED ENV{RSYNC_TARGET})
 123                 set (RSYNC_TARGET $ENV{RSYNC_TARGET})
 124         endif()
 125         if (DEFINED ENV{RSYNC_PREFIX})
 126                 set (RSYNC_PREFIX $ENV{RSYNC_PREFIX})
 127         endif()
 128
 129         set(
 130                 REMOTE_LAUNCH "Test on target with: ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh"
 131                 CACHE STRING "Command to start ${PROJECT_NAME} on remote target ${RSYNC_TARGET}"
 132         )
 133
 134         if(NOT RSYNC_TARGET OR NOT RSYNC_PREFIX)
 135                 message ("${Yellow}.. Warning: RSYNC_TARGET RSYNC_PREFIX not defined 'make remote-target-populate' not instanciated${ColourReset}")
 136                 add_custom_target(remote-target-populate
 137                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make remote-target-populate'${ColourReset}"
 138                         COMMAND exit -1
 139                 )
 140         else()
 141                 set(BINDINGS_REGEX "not_set")
 142                 if(DEFINED BINDINGS_LIST)
 143                         list(LENGTH BINDINGS_LIST BINDINGS_LIST_LENGTH)
 144                         if(BINDINGS_LIST_LENGTH EQUAL 1)
 145                                 list(GET BINDINGS_LIST 0 BINDINGS_REGEX)
 146                                 string(APPEND BINDINGS_REGEX ".so")
 147                         elseif(BINDINGS_LIST_LENGTH GREATER 1)
 148                                 foreach(B IN LISTS BINDINGS_LIST)
 149                                         STRING(APPEND BINDINGS_STR "${B}|")
 150                                 endforeach()
 151                                         STRING(REGEX REPLACE "^(.*)\\|$" "(\\1).so" BINDINGS_REGEX ${BINDINGS_STR})
 152                         endif()
 153                 endif()
 154
 155                 configure_files_in_dir(${SSH_TEMPLATE_DIR})
 156                 configure_files_in_dir(${GDB_TEMPLATE_DIR})
 157
 158                 add_custom_target(remote-target-populate
 159                         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/*.sh
 160                         COMMAND rsync -e "ssh -o StrictHostKeyChecking=no -o UserKnownHostsFile=/dev/null" --archive --delete ${PROJECT_PKG_BUILD_DIR}/ ${RSYNC_TARGET}:${RSYNC_PREFIX}/${PROJECT_NAME}
 161                         COMMENT "${REMOTE_LAUNCH}"
 162                 )
 163                 add_dependencies(remote-target-populate populate)
 164         endif()
 165 endmacro(remote_targets_populate)
 166
 167 macro(wgt_package_build)
 168         if(NOT EXISTS ${WIDGET_CONFIG_TEMPLATE})
 169                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need a config.xml template: please specify WIDGET_CONFIG_TEMPLATE correctly.${ColourReset}")
 170         endif()
 171         if(NOT EXISTS ${WGT_TEMPLATE_DIR}/icon-default.png)
 172                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need ${PROJECT_ICON} file in ${WGT_TEMPLATE_DIR} folder.${ColourReset}")
 173         endif()
 174     if(NOT WIDGET_TYPE)
 175         MESSAGE(FATAL_ERROR "WIDGET_TYPE must be set in your config.cmake.\neg.: set(WIDGET_TYPE application/vnd.agl.service)")
 176     endif()
 177
 178         if(NOT WIDGET_ENTRY_POINT)
 179                 set(WIDGET_ENTRY_POINT lib)
 180         endif()
 181
 182         add_custom_command(OUTPUT ${PROJECT_PKG_BUILD_DIR}/config.xml
 183                 COMMAND ${CMAKE_COMMAND} -DINFILE=${WIDGET_CONFIG_TEMPLATE} -DOUTFILE=${PROJECT_PKG_BUILD_DIR}/config.xml -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 184                 COMMAND cp ${WGT_TEMPLATE_DIR}/icon-default.png ${PROJECT_PKG_BUILD_DIR}/${PROJECT_ICON}
 185
 186         )
 187         add_custom_target(packaging_wgt DEPENDS ${PROJECT_PKG_BUILD_DIR}/config.xml)
 188
 189         # Fulup ??? copy any extra file in wgt/etc into populate package before building the widget
 190         file(GLOB PROJECT_CONF_FILES "${WGT_TEMPLATE_DIR}/etc/*")
 191         if(${PROJECT_CONF_FILES})
 192                 file(COPY "${WGT_TEMPLATE_DIR}/etc/*" DESTINATION ${PROJECT_PKG_BUILD_DIR}/etc/)
 193         endif(${PROJECT_CONF_FILES})
 194
 195         add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 196                 DEPENDS ${PROJECT_TARGETS}
 197                 COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${PROJECT_PKG_BUILD_DIR}
 198         )
 199
 200         add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 201         add_dependencies(widget populate packaging_wgt)
 202         set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}.wgt")
 203
 204         if(NOT RSYNC_TARGET)
 205                 message ("${Yellow}.. Warning: RSYNC_TARGET not defined 'make widget-target-install' not instanciated${ColourReset}")
 206                 add_custom_target(widget-target-install
 207                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make widget-target-install'${ColourReset}"
 208                         COMMAND exit -1
 209                 )
 210         else()
 211         configure_files_in_dir(${WGT_TEMPLATE_DIR})
 212         add_custom_target(widget-target-install
 213         DEPENDS widget
 214         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 215         COMMAND ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 216         )
 217 endif()
 218
 219         if(PACKAGE_MESSAGE)
 220         add_custom_command(TARGET widget
 221                 POST_BUILD
 222                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 223         endif()
 224 endmacro(wgt_package_build)
 225
 226 macro(rpm_package_build)
 227         add_custom_command(OUTPUT ${NPKG_PROJECT_NAME}.spec
 228                 DEPENDS ${PROJECT_TARGETS}
 229                                 archive
 230                                 packaging
 231                 COMMAND rpmbuild --define=\"%_sourcedir ${PROJECT_PKG_ENTRY_POINT}\" -ba  ${PROJECT_PKG_ENTRY_POINT}/${NPKG_PROJECT_NAME}.spec
 232         )
 233
 234         add_custom_target(rpm DEPENDS ${NPKG_PROJECT_NAME}.spec)
 235         add_dependencies(rpm populate packaging)
 236
 237         if(PACKAGE_MESSAGE)
 238         add_custom_command(TARGET rpm
 239                 POST_BUILD
 240                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 241         endif()
 242 endmacro(rpm_package_build)
 243
 244 macro(deb_package_build)
 245 #TODO
 246 endmacro(deb_package_build)
 247
 248 macro(project_package_build)
 249         if(EXISTS ${RPM_TEMPLATE_DIR})
 250                 rpm_package_build()
 251         endif()
 252
 253         if(EXISTS ${WGT_TEMPLATE_DIR})
 254                 wgt_package_build()
 255         endif()
 256
 257         if(EXISTS ${DEB_TEMPLATE_DIR})
 258                 deb_package_build()
 259         endif()
 260 endmacro(project_package_build)
 261
 262 macro(project_subdirs_add)
 263         set (ARGSLIST ${ARGN})
 264         list(LENGTH ARGSLIST ARGSNUM)
 265         if(${ARGSNUM} GREATER 0)
 266                 file(GLOB filelist "${ARGV0}")
 267         else()
 268         file(GLOB filelist "*")
 269         endif()
 270
 271         foreach(filename ${filelist})
 272                 if(EXISTS "${filename}/CMakeLists.txt")
 273                         add_subdirectory(${filename})
 274                 endif(EXISTS "${filename}/CMakeLists.txt")
 275         endforeach()
 276 endmacro(project_subdirs_add)
 277
 278 # Print developer helper message when build is done
 279 # -------------------------------------------------------
 280 macro(project_closing_msg)
 281         get_property(PROJECT_TARGETS_SET GLOBAL PROPERTY PROJECT_TARGETS SET)
 282         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 283         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS_SET})
 284                 add_custom_target(${PROJECT_NAME}_build_done ALL
 285                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 286                 )
 287                  add_dependencies(${PROJECT_NAME}_build_done
 288                         ${DEPENDENCIES_TARGET} ${PROJECT_TARGETS})
 289         endif()
 290 endmacro()