cmake/cmake.d/02-macros.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20 #--------------------------------------------------------------------------
  21 #  WARNING:
  22 #     Do not change this cmake template
  23 #     Customise your preferences in "./conf.d/cmake/config.cmake"
  24 #--------------------------------------------------------------------------
  25 # Generic useful macro
  26 # -----------------------
  27 macro(PROJECT_TARGET_ADD TARGET_NAME)
  28         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
  29         set(TARGET_NAME ${TARGET_NAME})
  30 endmacro(PROJECT_TARGET_ADD)
  31
  32 macro(PROJECT_PKGDEP_ADD PKG_NAME)
  33         set_property(GLOBAL APPEND PROPERTY PROJECT_PKG_DEPS ${PKG_NAME})
  34 endmacro(PROJECT_PKGDEP_ADD)
  35
  36 macro(defstr name value)
  37         add_definitions(-D${name}=${value})
  38 endmacro(defstr)
  39
  40 macro(configure_files_in_dir dir)
  41         file(GLOB filelist "${dir}/*in")
  42         foreach(file ${filelist})
  43                 get_filename_component(filename ${file} NAME)
  44                 string(REGEX REPLACE "target" "${RSYNC_TARGET}" destinationfile ${filename})
  45                 string(REGEX REPLACE ".in$" "" destinationfile ${destinationfile})
  46                 configure_file(${file} ${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile})
  47                 set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile}")
  48         endforeach()
  49 endmacro(configure_files_in_dir)
  50
  51 # Create custom target dedicated for HTML5 and DATA AGL target type
  52 macro(add_input_files INPUT_FILES)
  53         add_custom_target(${TARGET_NAME}
  54         DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
  55         )
  56
  57         add_custom_command(TARGET ${TARGET_NAME}
  58         PRE_BUILD
  59         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  60         COMMAND [ -f *xml ] && ${XML_CHECKER} ${INPUT_FILES}
  61         COMMAND [ -f *lua ] && ${LUA_CHECKER} ${INPUT_FILES}
  62         COMMAND [ -f *json ] && for f in ${INPUT_FILES}; do cat ${INPUT_FILES} | ${JSON_CHECKER}; done
  63         )
  64
  65         add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
  66         DEPENDS  ${INPUT_FILES}
  67         OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
  68         COMMAND mkdir -p ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
  69         COMMAND touch ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
  70         COMMAND cp -r ${INPUT_FILES} ${CMAKE_CURRENT_BINARY_DIR}/${TARGET_NAME}
  71         )
  72 endmacro()
  73 # Pre-packaging
  74 macro(project_targets_populate)
  75         # Default Widget default directory
  76         set(PACKAGE_BINDIR  ${PROJECT_PKG_BUILD_DIR}/bin)
  77         set(PACKAGE_ETCDIR  ${PROJECT_PKG_BUILD_DIR}/etc)
  78         set(PACKAGE_LIBDIR  ${PROJECT_PKG_BUILD_DIR}/lib)
  79         set(PACKAGE_HTTPDIR ${PROJECT_PKG_BUILD_DIR}/htdocs)
  80         set(PACKAGE_DATADIR ${PROJECT_PKG_BUILD_DIR}/data)
  81
  82         add_custom_command(OUTPUT ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR}
  83                 COMMAND mkdir -p ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR})
  84         add_custom_target(populate DEPENDS ${PACKAGE_BINDIR} ${PACKAGE_ETCDIR} ${PACKAGE_LIBDIR} ${PACKAGE_HTTPDIR} ${PACKAGE_DATADIR})
  85                 get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
  86         foreach(TARGET ${PROJECT_TARGETS})
  87                 get_target_property(T ${TARGET} LABELS)
  88                 if(T)
  89                         # Declaration of a custom command that will populate widget tree with the target
  90                         set(POPULE_PACKAGE_TARGET "project_populate_${TARGET}")
  91
  92                         get_target_property(P ${TARGET} PREFIX)
  93                         get_target_property(BD ${TARGET} BINARY_DIR)
  94                         get_target_property(SD ${TARGET} SOURCE_DIR)
  95                         get_target_property(OUT ${TARGET} OUTPUT_NAME)
  96
  97                         if(P MATCHES "NOTFOUND$")
  98                                 if (${T} STREQUAL "BINDING")
  99                                         set(P "lib")
 100                                 else()
 101                                         set(P "")
 102                                 endif()
 103                         endif()
 104
 105                         if(${T} STREQUAL "BINDING")
 106                                 list(APPEND BINDINGS_LIST "${P}${OUT}")
 107                                 add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${OUT}.so
 108                                         DEPENDS ${BD}/${P}${OUT}.so
 109                                         COMMAND mkdir -p ${PACKAGE_LIBDIR}
 110                                         COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
 111                                 )
 112                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${OUT}.so)
 113                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 114                                 add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 115                         elseif(${T} STREQUAL "BINDINGV2")
 116                                 add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${OUT}.so
 117                                         DEPENDS ${BD}/${P}${OUT}.so
 118                                         COMMAND mkdir -p ${PACKAGE_LIBDIR}
 119                                         COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
 120                                 )
 121                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${OUT}.so)
 122
 123                                 if (OPENAPI_DEF)
 124                                         add_custom_command(OUTPUT ${SD}/${OPENAPI_DEF}.h
 125                                                 DEPENDS ${SD}/${OPENAPI_DEF}.json
 126                                                 COMMAND afb-genskel ${SD}/${OPENAPI_DEF}.json > ${SD}/${OPENAPI_DEF}.h
 127                                         )
 128                                         add_custom_target("${TARGET}_GENSKEL" DEPENDS ${SD}/${OPENAPI_DEF}.h
 129                                                 COMMENT "Generating OpenAPI header file ${OPENAPI_DEF}.h")
 130                                         add_dependencies(${TARGET} "${TARGET}_GENSKEL")
 131                                 else()
 132                                         add_custom_command(OUTPUT ${SD}/${OUT}-apidef.h
 133                                                 DEPENDS ${SD}/${OUT}-apidef.json
 134                                                 COMMAND afb-genskel ${SD}/${OUT}-apidef.json > ${SD}/${OUT}-apidef.h
 135                                         )
 136                                         add_custom_target("${TARGET}_GENSKEL" DEPENDS ${SD}/${OUT}-apidef.h
 137                                                 COMMENT "Generating OpenAPI header file ${OUT}-apidef.h")
 138                                         add_dependencies(${TARGET} "${TARGET}_GENSKEL")
 139                                 endif()
 140                         elseif(${T} STREQUAL "EXECUTABLE")
 141                                 add_custom_command(OUTPUT ${PACKAGE_BINDIR}/${P}${OUT}
 142                                         DEPENDS ${BD}/${P}${OUT}
 143                                         COMMAND mkdir -p ${PACKAGE_BINDIR}
 144                                         COMMAND cp ${BD}/${P}${OUT} ${PACKAGE_BINDIR}
 145                                 )
 146                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_BINDIR}/${P}${OUT})
 147                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 148                                 add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 149                         elseif(${T} STREQUAL "HTDOCS")
 150                                 add_custom_command(OUTPUT ${PACKAGE_HTTPDIR}-xx
 151                                         DEPENDS ${BD}/${P}${OUT}
 152                                         COMMAND mkdir -p ${PACKAGE_HTTPDIR}
 153                                         COMMAND touch ${PACKAGE_HTTPDIR}
 154                                         COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_HTTPDIR}
 155                                 )
 156                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_HTTPDIR}-xx)
 157                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 158                                 add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 159                         elseif(${T} STREQUAL "DATA")
 160                                 add_custom_command(OUTPUT ${PACKAGE_DATADIR}-xx
 161                                         DEPENDS ${BD}/${P}${OUT}
 162                                         COMMAND mkdir -p ${PACKAGE_DATADIR}
 163                                         COMMAND touch ${PACKAGE_DATADIR}
 164                                         COMMAND cp -r ${BD}/${P}${OUT}/* ${PACKAGE_DATADIR}
 165                                 )
 166                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_DATADIR}-xx)
 167                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 168                                 add_dependencies(${POPULE_PACKAGE_TARGET} ${TARGET})
 169                         endif(${T} STREQUAL "BINDING")
 170                 elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 171                         MESSAGE(".. Warning: ${TARGET} ignored when packaging.")
 172                 endif()
 173         endforeach()
 174 endmacro(project_targets_populate)
 175
 176 macro(remote_targets_populate)
 177         if (DEFINED ENV{RSYNC_TARGET})
 178                 set (RSYNC_TARGET $ENV{RSYNC_TARGET})
 179         endif()
 180         if (DEFINED ENV{RSYNC_PREFIX})
 181                 set (RSYNC_PREFIX $ENV{RSYNC_PREFIX})
 182         endif()
 183
 184         set(
 185                 REMOTE_LAUNCH "Test on target with: ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh"
 186                 CACHE STRING "Command to start ${PROJECT_NAME} on remote target ${RSYNC_TARGET}"
 187         )
 188
 189         if(NOT RSYNC_TARGET OR NOT RSYNC_PREFIX)
 190                 message ("${Yellow}.. Warning: RSYNC_TARGET RSYNC_PREFIX not defined 'make remote-target-populate' not instanciated${ColourReset}")
 191                 add_custom_target(remote-target-populate
 192                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make remote-target-populate'${ColourReset}"
 193                         COMMAND exit -1
 194                 )
 195         else()
 196                 set(BINDINGS_REGEX "not_set")
 197                 if(DEFINED BINDINGS_LIST)
 198                         list(LENGTH BINDINGS_LIST BINDINGS_LIST_LENGTH)
 199                         if(BINDINGS_LIST_LENGTH EQUAL 1)
 200                                 list(GET BINDINGS_LIST 0 BINDINGS_REGEX)
 201                                 string(APPEND BINDINGS_REGEX ".so")
 202                         elseif(BINDINGS_LIST_LENGTH GREATER 1)
 203                                 foreach(B IN LISTS BINDINGS_LIST)
 204                                         STRING(APPEND BINDINGS_STR "${B}|")
 205                                 endforeach()
 206                                         STRING(REGEX REPLACE "^(.*)\\|$" "(\\1).so" BINDINGS_REGEX ${BINDINGS_STR})
 207                         endif()
 208                 endif()
 209
 210                 configure_files_in_dir(${TEMPLATE_DIR})
 211                 configure_files_in_dir(${TEMPLATE_DIR})
 212
 213                 add_custom_target(remote-target-populate
 214                         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/*.sh
 215                         COMMAND rsync -e "ssh -o StrictHostKeyChecking=no -o UserKnownHostsFile=/dev/null" --archive --delete ${PROJECT_PKG_BUILD_DIR}/ ${RSYNC_TARGET}:${RSYNC_PREFIX}/${PROJECT_NAME}
 216                         COMMENT "${REMOTE_LAUNCH}"
 217                 )
 218                 add_dependencies(remote-target-populate populate)
 219         endif()
 220 endmacro(remote_targets_populate)
 221
 222 macro(wgt_package_build)
 223         if(NOT EXISTS ${WIDGET_CONFIG_TEMPLATE})
 224                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need a config.xml template: please specify WIDGET_CONFIG_TEMPLATE correctly.${ColourReset}")
 225         endif()
 226         if(NOT EXISTS ${TEMPLATE_DIR}/icon-default.png)
 227                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need ${PROJECT_ICON} file in ${TEMPLATE_DIR} folder.${ColourReset}")
 228         endif()
 229     if(NOT WIDGET_TYPE)
 230         MESSAGE(FATAL_ERROR "WIDGET_TYPE must be set in your config.cmake.\neg.: set(WIDGET_TYPE application/vnd.agl.service)")
 231     endif()
 232
 233         if(NOT WIDGET_ENTRY_POINT)
 234                 set(WIDGET_ENTRY_POINT lib)
 235         endif()
 236
 237         add_custom_command(OUTPUT ${PROJECT_PKG_BUILD_DIR}/config.xml
 238                 COMMAND ${CMAKE_COMMAND} -DINFILE=${WIDGET_CONFIG_TEMPLATE} -DOUTFILE=${PROJECT_PKG_BUILD_DIR}/config.xml -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 239                 COMMAND cp ${TEMPLATE_DIR}/icon-default.png ${PROJECT_PKG_BUILD_DIR}/${PROJECT_ICON}
 240
 241         )
 242         add_custom_target(packaging_wgt DEPENDS ${PROJECT_PKG_BUILD_DIR}/config.xml)
 243
 244         # Fulup ??? copy any extra file in wgt/etc into populate package before building the widget
 245         file(GLOB PROJECT_CONF_FILES "${TEMPLATE_DIR}/etc/*")
 246         if(${PROJECT_CONF_FILES})
 247                 file(COPY "${TEMPLATE_DIR}/etc/*" DESTINATION ${PROJECT_PKG_BUILD_DIR}/etc/)
 248         endif(${PROJECT_CONF_FILES})
 249
 250         add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 251                 DEPENDS ${PROJECT_TARGETS}
 252                 COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${PROJECT_PKG_BUILD_DIR}
 253         )
 254
 255         add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 256         add_dependencies(widget populate packaging_wgt)
 257         set_property(DIRECTORY APPEND PROPERTY ADDITIONAL_MAKE_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}.wgt")
 258
 259         if(NOT RSYNC_TARGET)
 260                 message ("${Yellow}.. Warning: RSYNC_TARGET not defined 'make widget-target-install' not instanciated${ColourReset}")
 261                 add_custom_target(widget-target-install
 262                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make widget-target-install'${ColourReset}"
 263                         COMMAND exit -1
 264                 )
 265         else()
 266         configure_files_in_dir(${TEMPLATE_DIR})
 267         add_custom_target(widget-target-install
 268         DEPENDS widget
 269         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 270         COMMAND ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 271         )
 272 endif()
 273
 274         if(PACKAGE_MESSAGE)
 275         add_custom_command(TARGET widget
 276                 POST_BUILD
 277                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 278         endif()
 279 endmacro(wgt_package_build)
 280
 281 macro(rpm_package_build)
 282         add_custom_command(OUTPUT ${NPKG_PROJECT_NAME}.spec
 283                 DEPENDS ${PROJECT_TARGETS}
 284                                 archive
 285                                 packaging
 286                 COMMAND rpmbuild --define=\"%_sourcedir ${PROJECT_PKG_ENTRY_POINT}\" -ba  ${PROJECT_PKG_ENTRY_POINT}/${NPKG_PROJECT_NAME}.spec
 287         )
 288
 289         add_custom_target(rpm DEPENDS ${NPKG_PROJECT_NAME}.spec)
 290         add_dependencies(rpm populate packaging)
 291
 292         if(PACKAGE_MESSAGE)
 293         add_custom_command(TARGET rpm
 294                 POST_BUILD
 295                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 296         endif()
 297 endmacro(rpm_package_build)
 298
 299 macro(deb_package_build)
 300 #TODO
 301 endmacro(deb_package_build)
 302
 303 macro(project_package_build)
 304         if(EXISTS ${TEMPLATE_DIR})
 305                 rpm_package_build()
 306         endif()
 307
 308         if(EXISTS ${TEMPLATE_DIR})
 309                 wgt_package_build()
 310         endif()
 311
 312         if(EXISTS ${TEMPLATE_DIR})
 313                 deb_package_build()
 314         endif()
 315 endmacro(project_package_build)
 316
 317 macro(project_subdirs_add)
 318         set (ARGSLIST ${ARGN})
 319         list(LENGTH ARGSLIST ARGSNUM)
 320         if(${ARGSNUM} GREATER 0)
 321                 file(GLOB filelist "${ARGV0}")
 322         else()
 323         file(GLOB filelist "*")
 324         endif()
 325
 326         foreach(filename ${filelist})
 327                 if(EXISTS "${filename}/CMakeLists.txt")
 328                         add_subdirectory(${filename})
 329                 endif(EXISTS "${filename}/CMakeLists.txt")
 330         endforeach()
 331 endmacro(project_subdirs_add)
 332
 333 # Print developer helper message when build is done
 334 # -------------------------------------------------------
 335 macro(project_closing_msg)
 336         get_property(PROJECT_TARGETS_SET GLOBAL PROPERTY PROJECT_TARGETS SET)
 337         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 338         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS_SET})
 339                 add_custom_target(${PROJECT_NAME}_build_done ALL
 340                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 341                 )
 342                  add_dependencies(${PROJECT_NAME}_build_done
 343                         ${DEPENDENCIES_TARGET} ${PROJECT_TARGETS})
 344         endif()
 345 endmacro()