cmake/cmake.d/02-macros.cmake

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20 #--------------------------------------------------------------------------
  21 #  WARNING:
  22 #     Do not change this cmake template
  23 #     Customise your preferences in "./etc/config.cmake"
  24 #--------------------------------------------------------------------------
  25 # Generic useful macro
  26 # -----------------------
  27 macro(PROJECT_TARGET_ADD TARGET_NAME)
  28         set_property(GLOBAL APPEND PROPERTY PROJECT_TARGETS ${TARGET_NAME})
  29         set(TARGET_NAME ${TARGET_NAME})
  30 endmacro(PROJECT_TARGET_ADD)
  31
  32 macro(PROJECT_PKGDEP_ADD PKG_NAME)
  33         set_property(GLOBAL APPEND PROPERTY PROJECT_PKG_DEPS ${PKG_NAME})
  34 endmacro(PROJECT_PKGDEP_ADD)
  35
  36 macro(defstr name value)
  37         add_definitions(-D${name}=${value})
  38 endmacro(defstr)
  39
  40 macro(configure_files_in_dir dir)
  41         file(GLOB filelist "${dir}/*in")
  42         foreach(file ${filelist})
  43                 get_filename_component(filename ${file} NAME)
  44                 string(REGEX REPLACE "target" "${RSYNC_TARGET}" destinationfile ${filename})
  45                 configure_file(${file} ${CMAKE_CURRENT_BINARY_DIR}/target/${destinationfile})
  46         endforeach()
  47 endmacro(configure_files_in_dir)
  48
  49 # Pre-packaging
  50 macro(project_targets_populate)
  51         # Default Widget default directory
  52         set(PACKAGE_BINDIR  ${PROJECT_PKG_BUILD_DIR}/bin)
  53         set(PACKAGE_ETCDIR  ${PROJECT_PKG_BUILD_DIR}/etc)
  54         set(PACKAGE_LIBDIR  ${PROJECT_PKG_BUILD_DIR}/lib)
  55         set(PACKAGE_HTTPDIR ${PROJECT_PKG_BUILD_DIR}/htdocs)
  56         set(PACKAGE_DATADIR ${PROJECT_PKG_BUILD_DIR}/data)
  57
  58         add_custom_target(populate)
  59                 get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
  60         foreach(TARGET ${PROJECT_TARGETS})
  61                 get_target_property(T ${TARGET} LABELS)
  62                 if(T)
  63                         # Declaration of a custom command that will populate widget tree with the target
  64                         set(POPULE_PACKAGE_TARGET "project_populate_${TARGET}")
  65
  66                         get_target_property(P ${TARGET} PREFIX)
  67                         get_target_property(BD ${TARGET} BINARY_DIR)
  68                         get_target_property(SD ${TARGET} SOURCE_DIR)
  69                         get_target_property(OUT ${TARGET} OUTPUT_NAME)
  70
  71                         if(P MATCHES "NOTFOUND$")
  72                                 if (${T} STREQUAL "BINDING")
  73                                         set(P "lib")
  74                                 else()
  75                                         set(P "")
  76                                 endif()
  77                         endif()
  78
  79                         if(${T} STREQUAL "BINDING")
  80                                 add_custom_command(OUTPUT ${PACKAGE_LIBDIR}/${P}${TARGET}.so
  81                                         DEPENDS ${TARGET}
  82                                         COMMAND mkdir -p ${PACKAGE_LIBDIR}
  83                                         COMMAND cp ${BD}/${P}${OUT}.so ${PACKAGE_LIBDIR}
  84                                 )
  85                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_LIBDIR}/${P}${TARGET}.so)
  86                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
  87                         elseif(${T} STREQUAL "EXECUTABLE")
  88                                 add_custom_command(OUTPUT ${PACKAGE_BINDIR}/${P}${TARGET}
  89                                         DEPENDS ${TARGET}
  90                                         COMMAND mkdir -p ${PACKAGE_BINDIR}
  91                                         COMMAND cp ${BD}/${P}${OUT} ${PACKAGE_BINDIR}
  92                                 )
  93                                 add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_BINDIR}/${P}${TARGET})
  94                                 add_dependencies(populate ${POPULE_PACKAGE_TARGET})
  95                         elseif(${T} STREQUAL "HTDOCS")
  96                                 add_custom_command(OUTPUT ${PACKAGE_HTTPDIR}-xx
  97                                         DEPENDS ${TARGET}
  98                                         COMMAND mkdir -p ${PACKAGE_HTTPDIR}
  99                                         COMMAND touch ${PACKAGE_HTTPDIR}
 100                                         COMMAND cp -r ${SD}/* ${PACKAGE_HTTPDIR}
 101                                         COMMAND rm -f ${PACKAGE_HTTPDIR}/CMakeLists.txt
 102                                 )
 103                                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_HTTPDIR}-xx)
 104                                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 105                         elseif(${T} STREQUAL "DATA")
 106                                 add_custom_command(OUTPUT ${PACKAGE_DATADIR}-xx
 107                                         DEPENDS ${TARGET}
 108                                         COMMAND mkdir -p ${PACKAGE_DATADIR}
 109                                         COMMAND touch ${PACKAGE_DATADIR}
 110                                         COMMAND cp -r ${SD}/* ${PACKAGE_DATADIR}
 111                                         COMMAND rm -f ${PACKAGE_DATADIR}/CMakeLists.txt
 112                                 )
 113                                         add_custom_target(${POPULE_PACKAGE_TARGET} DEPENDS ${PACKAGE_DATADIR}-xx)
 114                                         add_dependencies(populate ${POPULE_PACKAGE_TARGET})
 115                         endif(${T} STREQUAL "BINDING")
 116                 elseif(${CMAKE_BUILD_TYPE} MATCHES "[Dd][Ee][Bb][Uu][Gg]")
 117                         MESSAGE(".. Warning: ${TARGET} ignored when packaging.")
 118                 endif()
 119         endforeach()
 120 endmacro(project_targets_populate)
 121
 122 macro(remote_targets_populate)
 123         if (DEFINED ENV{RSYNC_TARGET})
 124         set (RSYNC_TARGET $ENV{RSYNC_TARGET})
 125         endif()
 126         if (DEFINED ENV{RSYNC_PREFIX})
 127         set (RSYNC_PREFIX $ENV{RSYNC_PREFIX})
 128         endif()
 129
 130         set(
 131                 REMOTE_LAUNCH "Test on target with: ${CMAKE_CURRENT_BINARY_DIR}/target/start-on-${RSYNC_TARGET}.sh"
 132                 CACHE STRING "Command to start ${PROJECT_NAME} on remote target ${RSYNC_TARGET}"
 133         )
 134
 135         if(NOT RSYNC_TARGET OR NOT RSYNC_PREFIX)
 136                 message ("${Yellow}.. Warning: RSYNC_TARGET RSYNC_PREFIX not defined 'make remote-target-populate' not instanciated${ColourReset}")
 137                 add_custom_target(remote-target-populate
 138                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make remote-target-populate'${ColourReset}"
 139                         COMMAND exit -1
 140                 )
 141         else()
 142
 143                 configure_files_in_dir(${SSH_TEMPLATE_DIR})
 144                 configure_files_in_dir(${GDB_TEMPLATE_DIR})
 145
 146                 add_custom_target(remote-target-populate
 147                         DEPENDS populate
 148                         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/*.sh
 149                         COMMAND rsync -e "ssh -o StrictHostKeyChecking=no -o UserKnownHostsFile=/dev/null" --archive --delete ${PROJECT_PKG_BUILD_DIR}/ ${RSYNC_TARGET}:${RSYNC_PREFIX}/${PROJECT_NAME}
 150                         COMMENT "${REMOTE_LAUNCH}"
 151                 )
 152         endif()
 153 endmacro(remote_targets_populate)
 154
 155 macro(wgt_package_build)
 156         if(NOT EXISTS ${WIDGET_CONFIG_TEMPLATE})
 157                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need a config.xml template: please specify WIDGET_CONFIG_TEMPLATE correctly.${ColourReset}")
 158         endif()
 159         if(NOT EXISTS ${WGT_TEMPLATE_DIR}/icon-default.png)
 160                 MESSAGE(FATAL_ERROR "${Red}WARNING ! Missing mandatory files to build widget file.\nYou need ${PROJECT_ICON} file in ${WGT_TEMPLATE_DIR} folder.${ColourReset}")
 161         endif()
 162     if(NOT WIDGET_TYPE)
 163         MESSAGE(FATAL_ERROR "WIDGET_TYPE must be set in your config.cmake.\neg.: set(WIDGET_TYPE application/vnd.agl.service)")
 164     endif()
 165
 166         if(NOT WIDGET_ENTRY_POINT)
 167                 set(WIDGET_ENTRY_POINT lib)
 168         endif()
 169
 170         add_custom_command(OUTPUT ${PROJECT_PKG_BUILD_DIR}/config.xml
 171                 COMMAND ${CMAKE_COMMAND} -DINFILE=${WIDGET_CONFIG_TEMPLATE} -DOUTFILE=${PROJECT_PKG_BUILD_DIR}/config.xml -DPROJECT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR} -P ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_APP_TEMPLATES_DIR}/cmake/configure_file.cmake
 172                 COMMAND cp ${WGT_TEMPLATE_DIR}/icon-default.png ${PROJECT_PKG_BUILD_DIR}/${PROJECT_ICON}
 173
 174         )
 175         add_custom_target(packaging_wgt DEPENDS ${PROJECT_PKG_BUILD_DIR}/config.xml)
 176
 177         # Fulup ??? copy any extra file in wgt/etc into populate package before building the widget
 178         file(GLOB PROJECT_CONF_FILES "${WGT_TEMPLATE_DIR}/etc/*")
 179         if(${PROJECT_CONF_FILES})
 180                 file(COPY "${WGT_TEMPLATE_DIR}/etc/*" DESTINATION ${PROJECT_PKG_BUILD_DIR}/etc/)
 181         endif(${PROJECT_CONF_FILES})
 182
 183         add_custom_command(OUTPUT ${PROJECT_NAME}.wgt
 184                 DEPENDS ${PROJECT_TARGETS}
 185                 COMMAND wgtpkg-pack -f -o ${PROJECT_NAME}.wgt ${PROJECT_PKG_BUILD_DIR}
 186         )
 187
 188         add_custom_target(widget DEPENDS ${PROJECT_NAME}.wgt)
 189         add_dependencies(widget populate packaging_wgt)
 190         set(ADDITIONAL_MAKE_CLEAN_FILES, "${PROJECT_NAME}.wgt")
 191
 192         if(NOT RSYNC_TARGET)
 193                 message ("${Yellow}.. Warning: RSYNC_TARGET not defined 'make widget-target-install' not instanciated${ColourReset}")
 194                 add_custom_target(widget-target-install
 195                         COMMENT "${Red}*** Fatal: RSYNC_TARGET RSYNC_PREFIX environment variables required with 'make widget-target-install'${ColourReset}"
 196                         COMMAND exit -1
 197                 )
 198         else()
 199         configure_files_in_dir(${WGT_TEMPLATE_DIR})
 200         add_custom_target(widget-target-install
 201         DEPENDS widget
 202         COMMAND chmod +x ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 203         COMMAND ${CMAKE_CURRENT_BINARY_DIR}/target/install-wgt-on-${RSYNC_TARGET}.sh
 204         )
 205 endif()
 206
 207         if(PACKAGE_MESSAGE)
 208         add_custom_command(TARGET widget
 209                 POST_BUILD
 210                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 211         endif()
 212 endmacro(wgt_package_build)
 213
 214 macro(rpm_package_build)
 215         add_custom_command(OUTPUT ${NPKG_PROJECT_NAME}.spec
 216                 DEPENDS ${PROJECT_TARGETS}
 217                                 archive
 218                                 packaging
 219                 COMMAND rpmbuild --define=\"%_sourcedir ${PROJECT_PKG_ENTRY_POINT}\" -ba  ${PROJECT_PKG_ENTRY_POINT}/${NPKG_PROJECT_NAME}.spec
 220         )
 221
 222         add_custom_target(rpm DEPENDS ${NPKG_PROJECT_NAME}.spec)
 223         add_dependencies(rpm populate packaging)
 224         set(ADDITIONAL_MAKE_CLEAN_FILES, "${PROJECT_NAME}.spec")
 225
 226         if(PACKAGE_MESSAGE)
 227         add_custom_command(TARGET rpm
 228                 POST_BUILD
 229                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${PACKAGE_MESSAGE}")
 230         endif()
 231 endmacro(rpm_package_build)
 232
 233 macro(deb_package_build)
 234 #TODO
 235 endmacro(deb_package_build)
 236
 237 macro(project_package_build)
 238         if(EXISTS ${RPM_TEMPLATE_DIR})
 239                 rpm_package_build()
 240         endif()
 241
 242         if(EXISTS ${WGT_TEMPLATE_DIR})
 243                 wgt_package_build()
 244         endif()
 245
 246         if(EXISTS ${DEB_TEMPLATE_DIR})
 247                 deb_package_build()
 248         endif()
 249 endmacro(project_package_build)
 250
 251 macro(project_subdirs_add)
 252         set (ARGSLIST ${ARGN})
 253         list(LENGTH ARGSLIST ARGSNUM)
 254         if(${ARGSNUM} GREATER 0)
 255                 file(GLOB filelist "${ARGV0}")
 256         else()
 257         file(GLOB filelist "*")
 258         endif()
 259
 260         foreach(filename ${filelist})
 261                 if(EXISTS "${filename}/CMakeLists.txt")
 262                         add_subdirectory(${filename})
 263                 endif(EXISTS "${filename}/CMakeLists.txt")
 264         endforeach()
 265 endmacro(project_subdirs_add)
 266
 267 # Print developer helper message when build is done
 268 # -------------------------------------------------------
 269 macro(project_closing_msg)
 270         get_property(PROJECT_TARGETS_SET GLOBAL PROPERTY PROJECT_TARGETS SET)
 271         get_property(PROJECT_TARGETS GLOBAL PROPERTY PROJECT_TARGETS)
 272         if(CLOSING_MESSAGE AND ${PROJECT_TARGETS_SET})
 273                 add_custom_target(${PROJECT_NAME}_build_done ALL
 274                         COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 275                 )
 276                  add_dependencies(${PROJECT_NAME}_build_done
 277                         ${DEPENDENCIES_TARGET} ${PROJECT_TARGETS})
 278         endif()
 279 endmacro()