app/TachometerStyle.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2016 The Qt Company Ltd.
   4 ** Contact: https://www.qt.io/licensing/
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** Commercial License Usage
  10 ** Licensees holding valid commercial Qt licenses may use this file in
  11 ** accordance with the commercial license agreement provided with the
  12 ** Software or, alternatively, in accordance with the terms contained in
  13 ** a written agreement between you and The Qt Company. For licensing terms
  14 ** and conditions see https://www.qt.io/terms-conditions. For further
  15 ** information use the contact form at https://www.qt.io/contact-us.
  16 **
  17 ** BSD License Usage
  18 ** Alternatively, you may use this file under the terms of the BSD license
  19 ** as follows:
  20 **
  21 ** "Redistribution and use in source and binary forms, with or without
  22 ** modification, are permitted provided that the following conditions are
  23 ** met:
  24 **   * Redistributions of source code must retain the above copyright
  25 **     notice, this list of conditions and the following disclaimer.
  26 **   * Redistributions in binary form must reproduce the above copyright
  27 **     notice, this list of conditions and the following disclaimer in
  28 **     the documentation and/or other materials provided with the
  29 **     distribution.
  30 **   * Neither the name of The Qt Company Ltd nor the names of its
  31 **     contributors may be used to endorse or promote products derived
  32 **     from this software without specific prior written permission.
  33 **
  34 **
  35 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  36 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  37 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  38 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  39 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  40 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  41 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  42 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  43 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  44 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  45 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  46 **
  47 ** $QT_END_LICENSE$
  48 **
  49 ****************************************************************************/
  50
  51
  52 import QtQuick 2.2
  53 import QtQuick.Controls.Styles 1.4
  54 import QtQuick.Extras 1.4
  55
  56 DashboardGaugeStyle {
  57     id: tachometerStyle
  58     tickmarkStepSize: 1
  59     labelStepSize: 1
  60     needleLength: toPixels(0.85)
  61     needleBaseWidth: toPixels(0.08)
  62     needleTipWidth: toPixels(0.03)
  63
  64     tickmark: Rectangle {
  65         implicitWidth: toPixels(0.03)
  66         antialiasing: true
  67         implicitHeight: toPixels(0.08)
  68         color: styleData.index === 7 || styleData.index === 8 ? Qt.rgba(0.5, 0, 0, 1) : "#c8c8c8"
  69     }
  70
  71     minorTickmark: null
  72
  73     tickmarkLabel: Text {
  74         font.pixelSize: Math.max(6, toPixels(0.12))
  75         text: styleData.value
  76         color: styleData.index === 7 || styleData.index === 8 ? Qt.rgba(0.5, 0, 0, 1) : "#c8c8c8"
  77         antialiasing: true
  78     }
  79
  80     background: Canvas {
  81         onPaint: {
  82             var ctx = getContext("2d");
  83             ctx.reset();
  84             paintBackground(ctx);
  85
  86             ctx.beginPath();
  87             ctx.lineWidth = tachometerStyle.toPixels(0.08);
  88             ctx.strokeStyle = Qt.rgba(0.5, 0, 0, 1);
  89             var warningCircumference = maximumValueAngle - minimumValueAngle * 0.1;
  90             var startAngle = maximumValueAngle - 90;
  91             ctx.arc(outerRadius, outerRadius,
  92                 // Start the line in from the decorations, and account for the width of the line itself.
  93                 outerRadius - tickmarkInset - ctx.lineWidth / 2,
  94                 degToRad(startAngle - angleRange / 8 + angleRange * 0.015),
  95                 degToRad(startAngle - angleRange * 0.015), false);
  96             ctx.stroke();
  97         }
  98
  99         Text {
 100             id: rpmText
 101             font.pixelSize: tachometerStyle.toPixels(0.3)
 102             text: rpmInt
 103             color: "white"
 104             horizontalAlignment: Text.AlignRight
 105             anchors.horizontalCenter: parent.horizontalCenter
 106             anchors.top: parent.verticalCenter
 107             anchors.topMargin: 20
 108             visible: valueSource.displayNumericSpeeds === true
 109
 110             readonly property int rpmInt: valueSource.rpm
 111         }
 112         Text {
 113             text: "x1000"
 114             color: "white"
 115             font.pixelSize: tachometerStyle.toPixels(0.1)
 116             anchors.top: parent.top
 117             anchors.topMargin: parent.height / 4
 118             anchors.horizontalCenter: parent.horizontalCenter
 119         }
 120         Text {
 121             text: "RPM"
 122             color: "white"
 123             font.pixelSize: tachometerStyle.toPixels(0.1)
 124             anchors.top: rpmText.bottom
 125             anchors.horizontalCenter: parent.horizontalCenter
 126         }
 127     }
 128 }