app/IconGaugeStyle.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2016 The Qt Company Ltd.
   4 ** Contact: https://www.qt.io/licensing/
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** Commercial License Usage
  10 ** Licensees holding valid commercial Qt licenses may use this file in
  11 ** accordance with the commercial license agreement provided with the
  12 ** Software or, alternatively, in accordance with the terms contained in
  13 ** a written agreement between you and The Qt Company. For licensing terms
  14 ** and conditions see https://www.qt.io/terms-conditions. For further
  15 ** information use the contact form at https://www.qt.io/contact-us.
  16 **
  17 ** BSD License Usage
  18 ** Alternatively, you may use this file under the terms of the BSD license
  19 ** as follows:
  20 **
  21 ** "Redistribution and use in source and binary forms, with or without
  22 ** modification, are permitted provided that the following conditions are
  23 ** met:
  24 **   * Redistributions of source code must retain the above copyright
  25 **     notice, this list of conditions and the following disclaimer.
  26 **   * Redistributions in binary form must reproduce the above copyright
  27 **     notice, this list of conditions and the following disclaimer in
  28 **     the documentation and/or other materials provided with the
  29 **     distribution.
  30 **   * Neither the name of The Qt Company Ltd nor the names of its
  31 **     contributors may be used to endorse or promote products derived
  32 **     from this software without specific prior written permission.
  33 **
  34 **
  35 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  36 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  37 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  38 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  39 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  40 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  41 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  42 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  43 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  44 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  45 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  46 **
  47 ** $QT_END_LICENSE$
  48 **
  49 ****************************************************************************/
  50
  51
  52 import QtQuick 2.2
  53 import QtQuick.Controls.Styles 1.4
  54 import QtQuick.Extras 1.4
  55
  56 DashboardGaugeStyle {
  57     id: fuelGaugeStyle
  58     minimumValueAngle: -60
  59     maximumValueAngle: 60
  60     tickmarkStepSize: 1
  61     labelStepSize: 1
  62     labelInset: toPixels(-0.25)
  63     minorTickmarkCount: 3
  64
  65     needleLength: toPixels(0.85)
  66     needleBaseWidth: toPixels(0.08)
  67     needleTipWidth: toPixels(0.03)
  68
  69     halfGauge: true
  70
  71     property string icon: ""
  72     property color minWarningColor: "transparent"
  73     property color maxWarningColor: "transparent"
  74     readonly property real minWarningStartAngle: minimumValueAngle - 90
  75     readonly property real maxWarningStartAngle: maximumValueAngle - 90
  76
  77     tickmark: Rectangle {
  78         implicitWidth: toPixels(0.06)
  79         antialiasing: true
  80         implicitHeight: toPixels(0.2)
  81         color: "#c8c8c8"
  82     }
  83
  84     minorTickmark: Rectangle {
  85         implicitWidth: toPixels(0.03)
  86         antialiasing: true
  87         implicitHeight: toPixels(0.15)
  88         color: "#c8c8c8"
  89     }
  90
  91     background: Item {
  92         Canvas {
  93             anchors.fill: parent
  94             onPaint: {
  95                 var ctx = getContext("2d");
  96                 ctx.reset();
  97
  98                 paintBackground(ctx);
  99
 100                 if (minWarningColor != "transparent") {
 101                     ctx.beginPath();
 102                     ctx.lineWidth = fuelGaugeStyle.toPixels(0.08);
 103                     ctx.strokeStyle = minWarningColor;
 104                     ctx.arc(outerRadius, outerRadius,
 105                         // Start the line in from the decorations, and account for the width of the line itself.
 106                         outerRadius - tickmarkInset - ctx.lineWidth / 2,
 107                         degToRad(minWarningStartAngle),
 108                         degToRad(minWarningStartAngle + angleRange / (minorTickmarkCount + 1)), false);
 109                     ctx.stroke();
 110                 }
 111                 if (maxWarningColor != "transparent") {
 112                     ctx.beginPath();
 113                     ctx.lineWidth = fuelGaugeStyle.toPixels(0.08);
 114                     ctx.strokeStyle = maxWarningColor;
 115                     ctx.arc(outerRadius, outerRadius,
 116                         // Start the line in from the decorations, and account for the width of the line itself.
 117                         outerRadius - tickmarkInset - ctx.lineWidth / 2,
 118                         degToRad(maxWarningStartAngle - angleRange / (minorTickmarkCount + 1)),
 119                         degToRad(maxWarningStartAngle), false);
 120                     ctx.stroke();
 121                 }
 122             }
 123         }
 124
 125         Image {
 126             source: icon
 127             anchors.bottom: parent.verticalCenter
 128             anchors.bottomMargin: toPixels(0.3)
 129             anchors.horizontalCenter: parent.horizontalCenter
 130             width: toPixels(0.3)
 131             height: width
 132             fillMode: Image.PreserveAspectFit
 133         }
 134     }
 135 }