CAN-binder/CMakeLists.txt

   1 ###########################################################################
   2 # Copyright 2015, 2016, 2017 IoT.bzh
   3 #
   4 # author: Fulup Ar Foll <fulup@iot.bzh>
   5 # contrib: Romain Forlot <romain.forlot@iot.bzh>
   6 #
   7 # Licensed under the Apache License, Version 2.0 (the "License");
   8 # you may not use this file except in compliance with the License.
   9 # You may obtain a copy of the License at
  10 #
  11 #     http://www.apache.org/licenses/LICENSE-2.0
  12 #
  13 # Unless required by applicable law or agreed to in writing, software
  14 # distributed under the License is distributed on an "AS IS" BASIS,
  15 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16 # See the License for the specific language governing permissions and
  17 # limitations under the License.
  18 ###########################################################################
  19
  20
  21 #--------------------------------------------------------------------------
  22 #  WARNING:
  23 #     Do not change this cmake template
  24 #     Customise your preferences in "./etc/config.cmake"
  25 #--------------------------------------------------------------------------
  26
  27
  28 # Generic useful macro
  29 # -----------------------
  30 macro(PROJECT_TARGET_ADD TARGET_NAME)
  31         set(PROJECT_TARGETS ${PROJECT_TARGETS} ${TARGET_NAME} CACHE INTERNAL PROJECT_TARGETS)
  32         set(TARGET_NAME ${TARGET_NAME})
  33 endmacro(PROJECT_TARGET_ADD)
  34
  35 macro(defstr name value)
  36         add_definitions(-D${name}=${value})
  37 endmacro(defstr)
  38
  39 macro(setc name value)
  40         if(NOT DEFINED ${name})
  41         set(${name} ${value})
  42         endif(NOT DEFINED ${name})
  43 endmacro(setc)
  44
  45 # Dumb macro to add each directory under a path. Make sure we grab all header files!
  46 macro(fill_include_dir path)
  47         file(GLOB_RECURSE dirlist LIST_DIRECTORIES true "${path}/*")
  48         foreach(filename ${dirlist})
  49                 if(IS_DIRECTORY ${filename})
  50                         include_directories(${filename})
  51                 endif(IS_DIRECTORY ${filename})
  52         endforeach()
  53 endmacro(fill_include_dir)
  54
  55 # Helper function to retrieve source files from a library repo.
  56 function(find_source_files path)
  57         file(GLOB_RECURSE cfiles "${path}/*.[c]")
  58         file(GLOB_RECURSE cppfiles "${path}/*.cpp")
  59         foreach(filename ${cfiles})
  60                 if(NOT ${filename} MATCHES ".*([Tt]est|[Ee]xample|[Ss]ample).*")
  61                         string(APPEND sources "${filename};")
  62                 endif(NOT ${filename} MATCHES ".*([Tt]est|[Ee]xample|[Ss]ample).*")
  63         endforeach()
  64         foreach(filename ${cppfiles})
  65                 if(NOT ${filename} MATCHES ".*([Tt]est|[Ee]xample|[Ss]ample).*")
  66                         string(APPEND sources "${filename};")
  67                 endif(NOT ${filename} MATCHES ".*([Tt]est|[Ee]xample|[Ss]ample).*")
  68         endforeach()
  69         set(sources_files ${sources} PARENT_SCOPE)
  70 endfunction(find_source_files)
  71
  72 # WGT packaging function. TYPE can be HTML5, NATIVE, HTML5-HYBRID or BINDING
  73 macro(build_widget type)
  74         message(STATUS "Creation of ${TARGET_NAME}.wgt package for AppFW")
  75
  76         configure_file(${PROJECT_WGT_DIR}/config.xml config.xml)
  77
  78         if(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_WGT_DIR}/etc")
  79                 file(GLOB conf_files "${PROJECT_WGT_DIR}/etc/*")
  80                 foreach(filename ${conf_files})
  81                         STRING(REGEX REPLACE "^.*/(.*)$" "\\1" shortname ${filename})
  82                         message(STATUS "Copying config file ${shortname}")
  83                         configure_file(${filename} ${shortname})
  84                 endforeach()
  85         endif(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_WGT_DIR}/etc")
  86
  87         # Include HTML5 files to be packaged
  88         if(${type} STREQUAL "HTML5")
  89                 file(GLOB_RECURSE HTML5FILES app/*)
  90
  91                 if(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/gulpfile.js")
  92                         set(HTML5FILES ${HTML5FILES} "${CMAKE_CURRENT_SOURCE_DIR}/gulpfile.js")
  93                 endif(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/gulpfile.js")
  94
  95                 if(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/bower.json")
  96                         set(HTML5FILES ${HTML5FILES} "${CMAKE_CURRENT_SOURCE_DIR}/bower.json")
  97                 endif(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/bower.json")
  98
  99                 if(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/package.json")
 100                         set(HTML5FILES ${HTML5FILES} "${CMAKE_CURRENT_SOURCE_DIR}/package.json")
 101                 endif(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/package.json")
 102         endif(${type} STREQUAL "HTML5")
 103
 104         if(${type} STREQUAL "HTML5")
 105                 add_custom_command(
 106                         OUTPUT ${TARGET_NAME}.wgt
 107                         DEPENDS ${HTML5FILES} ${PROJECT_WGT_DIR}/config.xml
 108                         COMMAND rm -rf package
 109                         COMMAND mkdir -p package/lib package/htdocs package/etc package/bin
 110                         COMMAND cd ${CMAKE_CURRENT_SOURCE_DIR} && gulp widget-config-prod
 111                         COMMAND cp -a dist.prod/* ${CMAKE_CURRENT_BINARY_DIR}/package/htdocs
 112                 )
 113         endif(${type} STREQUAL "HTML5")
 114
 115         if(${type} STREQUAL "HTML5-HYBRID")
 116                 add_custom_command(
 117                         OUTPUT ${TARGET_NAME}.wgt
 118                         DEPENDS ${HTML5FILES} ${PROJECT_WGT_DIR}/config.xml
 119                         COMMAND rm -rf package
 120                         COMMAND mkdir -p package/lib package/htdocs package/etc package/bin
 121                         COMMAND cp ${TARGET_NAME}.so package/lib
 122                 )
 123         endif(${type} STREQUAL "HTML5-HYBRID")
 124
 125         if(${type} STREQUAL "BINDING")
 126                 add_custom_command(
 127                         OUTPUT ${TARGET_NAME}.wgt
 128                         DEPENDS ${PROJECT_WGT_DIR}/config.xml
 129                         COMMAND rm -rf package
 130                         COMMAND mkdir -p package/lib package/htdocs package/etc package/bin
 131                         COMMAND cp ${TARGET_NAME}.so package/lib
 132                 )
 133         endif(${type} STREQUAL "BINDING")
 134
 135         if(${type} STREQUAL "NATIVE")
 136                 add_custom_command(
 137                         OUTPUT ${TARGET_NAME}.wgt
 138                         DEPENDS ${PROJECT_WGT_DIR}/config.xml
 139                         COMMAND rm -rf package
 140                         COMMAND mkdir -p package/lib package/htdocs package/etc package/bin
 141                         COMMAND cp ${TARGET_NAME} package/bin
 142                 )
 143         endif(${type} STREQUAL "NATIVE")
 144
 145         add_custom_command(
 146                 OUTPUT ${TARGET_NAME}.wgt
 147                 COMMAND cp config.xml package/
 148                 COMMAND cp ${conf_files} package/etc
 149                 COMMAND cp ${CMAKE_CURRENT_SOURCE_DIR}/packaging/wgt/${PROJECT_ICON} package/icon.png
 150                 COMMAND wgtpkg-pack -f -o ${TARGET_NAME}.wgt package
 151                 APPEND
 152         )
 153         add_custom_target(widget ALL DEPENDS ${TARGET_NAME}.wgt)
 154 endmacro()
 155
 156 CMAKE_MINIMUM_REQUIRED(VERSION 3.3)
 157 setc(CMAKE_BUILD_TYPE Debug)
 158 set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 159 set(CMP0048 1)
 160
 161 # Compiler selection should append before project definition
 162 # -----------------------------------------------------------
 163 foreach (GCC_VERSION "6" "5")
 164         execute_process(COMMAND gcc-${GCC_VERSION} -dumpversion RESULT_VARIABLE GCCRC OUTPUT_QUIET ERROR_QUIET)
 165         if(GCCRC EQUAL 0)
 166                 set(CMAKE_C_COMPILER "gcc-${GCC_VERSION}")
 167                 set(CMAKE_CXX_COMPILER "g++-${GCC_VERSION}")
 168                 set(CMAKE_C_VERSION ${GCC_VERSION})
 169                 break()
 170         endif(GCCRC EQUAL 0)
 171 endforeach(GCC_VERSION)
 172
 173 # Include project configuration
 174 # ------------------------------
 175 include(${CMAKE_CURRENT_SOURCE_DIR}/etc/config.cmake)
 176 project(${NAME} VERSION ${VERSION})
 177 setc(PROJECT_PRETTY_NAME "${PRETTY_NAME}")
 178 setc(PROJECT_DESCRIPTION "${DESCRIPTION}")
 179 setc(PROJECT_WGT_DIR "packaging/wgt")
 180 setc(PROJECT_LIBDIR "libs")
 181 setc(PROJECT_RESOURCES "data")
 182
 183 message(STATUS "")
 184 message(STATUS "Project=${PROJECT_NAME}/${VERSION}[${PRETTY_NAME} ${DESCRIPTION}]")
 185 message(STATUS "")
 186 message(STATUS "gcc/g++ version-${CMAKE_C_VERSION}.x selected")
 187
 188 INCLUDE(FindPkgConfig)
 189 INCLUDE(CheckIncludeFiles)
 190 INCLUDE(CheckLibraryExists)
 191 INCLUDE(GNUInstallDirs)
 192
 193 # Default compilation options
 194 ############################################################################
 195 link_libraries(-Wl,--as-needed -Wl,--gc-sections)
 196 add_compile_options(-Wall -Wextra -Wconversion)
 197 add_compile_options(-Wno-unused-parameter) # frankly not using a parameter does it care?
 198 add_compile_options(-Wno-sign-compare -Wno-sign-conversion)
 199 add_compile_options(-Werror=maybe-uninitialized)
 200 add_compile_options(-Werror=implicit-function-declaration)
 201 add_compile_options(-ffunction-sections -fdata-sections)
 202 add_compile_options(-fPIC)
 203 add_compile_options(-g)
 204
 205 setc(CMAKE_C_FLAGS_PROFILING   "-g -O2 -pg -Wp,-U_FORTIFY_SOURCE")
 206 setc(CMAKE_C_FLAGS_DEBUG       "-g -O2 -ggdb -Wp,-U_FORTIFY_SOURCE")
 207 setc(CMAKE_C_FLAGS_RELEASE     "-O2")
 208 setc(CMAKE_C_FLAGS_CCOV        "-g -O2 --coverage")
 209
 210 set(CMAKE_CXX_FLAGS_PROFILING    "-g -O0 -std=c++11 -pg -Wp,-U_FORTIFY_SOURCE")
 211 set(CMAKE_CXX_FLAGS_DEBUG        "-g -O0 -std=c++11 -ggdb -Wp,-U_FORTIFY_SOURCE")
 212 set(CMAKE_CXX_FLAGS_RELEASE      "-g -O2 -std=c++11")
 213 set(CMAKE_CXX_FLAGS_CCOV "-g -O2 -std=c++11 --coverage")
 214
 215 setc(CMAKE_INSTALL_PREFIX      "${CMAKE_SOURCE_DIR}/Install")
 216
 217 # (BUG!!!) as PKG_CONFIG_PATH does not work [should be en env variable]
 218 setc(PKG_CONFIG_USE_CMAKE_PREFIX_PATH 1)
 219
 220 # Loop on required package and add options
 221 foreach (PKG_CONFIG ${PKG_REQUIRED_LIST})
 222         PKG_CHECK_MODULES(${PKG_CONFIG} REQUIRED ${PKG_CONFIG})
 223
 224         INCLUDE_DIRECTORIES(${${PKG_CONFIG}_INCLUDE_DIRS})
 225         list (APPEND link_libraries ${${PKG_CONFIG}_LIBRARIES})
 226         add_compile_options (${${PKG_CONFIG}_CFLAGS})
 227 endforeach(PKG_CONFIG)
 228
 229 # Optional LibEfence Malloc debug library
 230 IF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 231 CHECK_LIBRARY_EXISTS(efence malloc "" HAVE_LIBEFENCE)
 232 IF(HAVE_LIBEFENCE)
 233         MESSAGE(STATUS "Linking with ElectricFence for debugging purposes...")
 234         SET(libefence_LIBRARIES "-lefence")
 235         list (APPEND link_libraries libefence_LIBRARIES})
 236 ENDIF(HAVE_LIBEFENCE)
 237 ENDIF(CMAKE_BUILD_TYPE MATCHES DEBUG)
 238
 239 # set default include directories
 240 #INCLUDE_DIRECTORIES(${EXTRA_INCLUDE_DIRS})
 241 # Brutal but efficace:
 242 fill_include_dir(${CMAKE_CURRENT_SOURCE_DIR})
 243
 244 # If no install dir try to guest some smart default
 245 if(BINDINGS_INSTALL_PREFIX)
 246         set(BINDINGS_INSTALL_DIR ${BINDINGS_INSTALL_PREFIX}/${PROJECT_NAME})
 247 else()
 248         set(BINDINGS_INSTALL_DIR ${CMAKE_INSTALL_FULL_LIBDIR}/${PROJECT_NAME})
 249 endif()
 250
 251 # Default Linkflag
 252 if(NOT BINDINGS_LINK_FLAG)
 253         set(BINDINGS_LINK_FLAG "-Wl,--version-script=${CMAKE_SOURCE_DIR}/etc/export.map")
 254 endif()
 255
 256 # Bindings to compile
 257 # --------------------
 258 file(GLOB filelist "*")
 259 foreach(filename ${filelist})
 260 if(EXISTS "${filename}/CMakeLists.txt")
 261         add_subdirectory(${filename})
 262 endif(EXISTS "${filename}/CMakeLists.txt")
 263 endforeach()
 264
 265 # Add a dummy target to enable global dependency order
 266 # -----------------------------------------------------
 267 if(EXTRA_DEPENDENCIES_ORDER)
 268         set(DEPENDENCIES_TARGET ${PROJECT_NAME}_extra_dependencies)
 269         add_custom_target(${DEPENDENCIES_TARGET} ALL
 270                 DEPENDS ${EXTRA_DEPENDENCY_ORDER}
 271         )
 272 endif()
 273
 274 # Cmake does not maintain targets list before 3.7
 275 # -------------------------------------------------
 276 if(${CMAKE_VERSION} VERSION_LESS 3.7)
 277         set(GLOBAL_TARGET_LIST ${PROJECT_TARGETS})
 278 else()
 279         get_property(GLOBAL_TARGET_LIST GLOBAL PROPERTY GlobalTargetList)
 280 endif()
 281
 282 # Print developer helper message when everything is done
 283 # -------------------------------------------------------
 284 if(CLOSING_MESSAGE AND GLOBAL_TARGET_LIST)
 285         add_custom_target(${PROJECT_NAME}_done ALL
 286                 DEPENDS ${DEPENDENCIES_TARGET} ${GLOBAL_TARGET_LIST}
 287                 COMMAND ${CMAKE_COMMAND} -E cmake_echo_color --cyan "++ ${CLOSING_MESSAGE}"
 288         )
 289 endif()